renatofilho@320: # This file is part of Autoconf.                       -*- Autoconf -*-
renatofilho@320: 
renatofilho@320: # Copyright (C) 2004 Oren Ben-Kiki
renatofilho@320: # This file is distributed under the same terms as the Autoconf macro files.
renatofilho@320: 
renatofilho@320: # Generate automatic documentation using Doxygen. Works in concert with the
renatofilho@320: # aminclude.m4 file and a compatible doxygen configuration file. Defines the
renatofilho@320: # following public macros:
renatofilho@320: #
renatofilho@320: # DX_???_FEATURE(ON|OFF) - control the default setting fo a Doxygen feature.
renatofilho@320: # Supported features are 'DOXYGEN' itself, 'DOT' for generating graphics,
renatofilho@320: # 'HTML' for plain HTML, 'CHM' for compressed HTML help (for MS users), 'CHI'
renatofilho@320: # for generating a seperate .chi file by the .chm file, and 'MAN', 'RTF',
renatofilho@320: # 'XML', 'PDF' and 'PS' for the appropriate output formats. The environment
renatofilho@320: # variable DOXYGEN_PAPER_SIZE may be specified to override the default 'a4wide'
renatofilho@320: # paper size.
renatofilho@320: #
renatofilho@320: # By default, HTML, PDF and PS documentation is generated as this seems to be
renatofilho@320: # the most popular and portable combination. MAN pages created by Doxygen are
renatofilho@320: # usually problematic, though by picking an appropriate subset and doing some
renatofilho@320: # massaging they might be better than nothing. CHM and RTF are specific for MS
renatofilho@320: # (note that you can't generate both HTML and CHM at the same time). The XML is
renatofilho@320: # rather useless unless you apply specialized post-processing to it.
renatofilho@320: #
renatofilho@320: # The macro mainly controls the default state of the feature. The use can
renatofilho@320: # override the default by specifying --enable or --disable. The macros ensure
renatofilho@320: # that contradictory flags are not given (e.g., --enable-doxygen-html and
renatofilho@320: # --enable-doxygen-chm, --enable-doxygen-anything with --disable-doxygen, etc.)
renatofilho@320: # Finally, each feature will be automatically disabled (with a warning) if the
renatofilho@320: # required programs are missing.
renatofilho@320: #
renatofilho@320: # Once all the feature defaults have been specified, call DX_INIT_DOXYGEN with
renatofilho@320: # the following parameters: a one-word name for the project for use as a
renatofilho@320: # filename base etc., an optional configuration file name (the default is
renatofilho@320: # 'Doxyfile', the same as Doxygen's default), and an optional output directory
renatofilho@320: # name (the default is 'doxygen-doc').
renatofilho@320: 
renatofilho@320: ## ----------##
renatofilho@320: ## Defaults. ##
renatofilho@320: ## ----------##
renatofilho@320: 
renatofilho@320: DX_ENV=""
renatofilho@320: AC_DEFUN([DX_FEATURE_doc],  ON)
renatofilho@320: AC_DEFUN([DX_FEATURE_dot],  ON)
renatofilho@320: AC_DEFUN([DX_FEATURE_man],  OFF)
renatofilho@320: AC_DEFUN([DX_FEATURE_html], ON)
renatofilho@320: AC_DEFUN([DX_FEATURE_chm],  OFF)
renatofilho@320: AC_DEFUN([DX_FEATURE_chi],  OFF)
renatofilho@320: AC_DEFUN([DX_FEATURE_rtf],  OFF)
renatofilho@320: AC_DEFUN([DX_FEATURE_xml],  OFF)
renatofilho@320: AC_DEFUN([DX_FEATURE_pdf],  ON)
renatofilho@320: AC_DEFUN([DX_FEATURE_ps],   ON)
renatofilho@320: 
renatofilho@320: ## --------------- ##
renatofilho@320: ## Private macros. ##
renatofilho@320: ## --------------- ##
renatofilho@320: 
renatofilho@320: # DX_ENV_APPEND(VARIABLE, VALUE)
renatofilho@320: # ------------------------------
renatofilho@320: # Append VARIABLE="VALUE" to DX_ENV for invoking doxygen.
renatofilho@320: AC_DEFUN([DX_ENV_APPEND], [AC_SUBST([DX_ENV], ["$DX_ENV $1='$2'"])])
renatofilho@320: 
renatofilho@320: # DX_DIRNAME_EXPR
renatofilho@320: # ---------------
renatofilho@320: # Expand into a shell expression prints the directory part of a path.
renatofilho@320: AC_DEFUN([DX_DIRNAME_EXPR],
renatofilho@320:          [[expr ".$1" : '\(\.\)[^/]*$' \| "x$1" : 'x\(.*\)/[^/]*$']])
renatofilho@320: 
renatofilho@320: # DX_IF_FEATURE(FEATURE, IF-ON, IF-OFF)
renatofilho@320: # -------------------------------------
renatofilho@320: # Expands according to the M4 (static) status of the feature.
renatofilho@320: AC_DEFUN([DX_IF_FEATURE], [ifelse(DX_FEATURE_$1, ON, [$2], [$3])])
renatofilho@320: 
renatofilho@320: # DX_REQUIRE_PROG(VARIABLE, PROGRAM)
renatofilho@320: # ----------------------------------
renatofilho@320: # Require the specified program to be found for the DX_CURRENT_FEATURE to work.
renatofilho@320: AC_DEFUN([DX_REQUIRE_PROG], [
renatofilho@320: AC_PATH_TOOL([$1], [$2])
renatofilho@320: if test "$DX_FLAG_[]DX_CURRENT_FEATURE$$1" = 1; then
renatofilho@320:     AC_MSG_WARN([$2 not found - will not DX_CURRENT_DESCRIPTION])
renatofilho@320:     AC_SUBST([DX_FLAG_[]DX_CURRENT_FEATURE], 0)
renatofilho@320: fi
renatofilho@320: ])
renatofilho@320: 
renatofilho@320: # DX_TEST_FEATURE(FEATURE)
renatofilho@320: # ------------------------
renatofilho@320: # Expand to a shell expression testing whether the feature is active.
renatofilho@320: AC_DEFUN([DX_TEST_FEATURE], [test "$DX_FLAG_$1" = 1])
renatofilho@320: 
renatofilho@320: # DX_CHECK_DEPEND(REQUIRED_FEATURE, REQUIRED_STATE)
renatofilho@320: # -------------------------------------------------
renatofilho@320: # Verify that a required features has the right state before trying to turn on
renatofilho@320: # the DX_CURRENT_FEATURE.
renatofilho@320: AC_DEFUN([DX_CHECK_DEPEND], [
renatofilho@320: test "$DX_FLAG_$1" = "$2" \
renatofilho@320: || AC_MSG_ERROR([doxygen-DX_CURRENT_FEATURE ifelse([$2], 1,
renatofilho@320:                             requires, contradicts) doxygen-DX_CURRENT_FEATURE])
renatofilho@320: ])
renatofilho@320: 
renatofilho@320: # DX_CLEAR_DEPEND(FEATURE, REQUIRED_FEATURE, REQUIRED_STATE)
renatofilho@320: # ----------------------------------------------------------
renatofilho@320: # Turn off the DX_CURRENT_FEATURE if the required feature is off.
renatofilho@320: AC_DEFUN([DX_CLEAR_DEPEND], [
renatofilho@320: test "$DX_FLAG_$1" = "$2" || AC_SUBST([DX_FLAG_[]DX_CURRENT_FEATURE], 0)
renatofilho@320: ])
renatofilho@320: 
renatofilho@320: # DX_FEATURE_ARG(FEATURE, DESCRIPTION,
renatofilho@320: #                CHECK_DEPEND, CLEAR_DEPEND,
renatofilho@320: #                REQUIRE, DO-IF-ON, DO-IF-OFF)
renatofilho@320: # --------------------------------------------
renatofilho@320: # Parse the command-line option controlling a feature. CHECK_DEPEND is called
renatofilho@320: # if the user explicitly turns the feature on (and invokes DX_CHECK_DEPEND),
renatofilho@320: # otherwise CLEAR_DEPEND is called to turn off the default state if a required
renatofilho@320: # feature is disabled (using DX_CLEAR_DEPEND). REQUIRE performs additional
renatofilho@320: # requirement tests (DX_REQUIRE_PROG). Finally, an automake flag is set and
renatofilho@320: # DO-IF-ON or DO-IF-OFF are called according to the final state of the feature.
renatofilho@320: AC_DEFUN([DX_ARG_ABLE], [
renatofilho@320:     AC_DEFUN([DX_CURRENT_FEATURE], [$1])
renatofilho@320:     AC_DEFUN([DX_CURRENT_DESCRIPTION], [$2])
renatofilho@320:     AC_ARG_ENABLE(doxygen-$1,
renatofilho@320:                   [AS_HELP_STRING(DX_IF_FEATURE([$1], [--disable-doxygen-$1],
renatofilho@320:                                                       [--enable-doxygen-$1]),
renatofilho@320:                                   DX_IF_FEATURE([$1], [don't $2], [$2]))],
renatofilho@320:                   [
renatofilho@320: case "$enableval" in
renatofilho@320: #(
renatofilho@320: y|Y|yes|Yes|YES)
renatofilho@320:     AC_SUBST([DX_FLAG_$1], 1)
renatofilho@320:     $3
renatofilho@320: ;; #(
renatofilho@320: n|N|no|No|NO)
renatofilho@320:     AC_SUBST([DX_FLAG_$1], 0)
renatofilho@320: ;; #(
renatofilho@320: *)
renatofilho@320:     AC_MSG_ERROR([invalid value '$enableval' given to doxygen-$1])
renatofilho@320: ;;
renatofilho@320: esac
renatofilho@320: ], [
renatofilho@320: AC_SUBST([DX_FLAG_$1], [DX_IF_FEATURE([$1], 1, 0)])
renatofilho@320: $4
renatofilho@320: ])
renatofilho@320: if DX_TEST_FEATURE([$1]); then
renatofilho@320:     $5
renatofilho@320:     :
renatofilho@320: fi
renatofilho@320: if DX_TEST_FEATURE([$1]); then
renatofilho@320:     AM_CONDITIONAL(DX_COND_$1, :)
renatofilho@320:     $6
renatofilho@320:     :
renatofilho@320: else
renatofilho@320:     AM_CONDITIONAL(DX_COND_$1, false)
renatofilho@320:     $7
renatofilho@320:     :
renatofilho@320: fi
renatofilho@320: ])
renatofilho@320: 
renatofilho@320: ## -------------- ##
renatofilho@320: ## Public macros. ##
renatofilho@320: ## -------------- ##
renatofilho@320: 
renatofilho@320: # DX_XXX_FEATURE(DEFAULT_STATE)
renatofilho@320: # -----------------------------
renatofilho@320: AC_DEFUN([DX_DOXYGEN_FEATURE], [AC_DEFUN([DX_FEATURE_doc],  [$1])])
renatofilho@320: AC_DEFUN([DX_MAN_FEATURE],     [AC_DEFUN([DX_FEATURE_man],  [$1])])
renatofilho@320: AC_DEFUN([DX_HTML_FEATURE],    [AC_DEFUN([DX_FEATURE_html], [$1])])
renatofilho@320: AC_DEFUN([DX_CHM_FEATURE],     [AC_DEFUN([DX_FEATURE_chm],  [$1])])
renatofilho@320: AC_DEFUN([DX_CHI_FEATURE],     [AC_DEFUN([DX_FEATURE_chi],  [$1])])
renatofilho@320: AC_DEFUN([DX_RTF_FEATURE],     [AC_DEFUN([DX_FEATURE_rtf],  [$1])])
renatofilho@320: AC_DEFUN([DX_XML_FEATURE],     [AC_DEFUN([DX_FEATURE_xml],  [$1])])
renatofilho@320: AC_DEFUN([DX_XML_FEATURE],     [AC_DEFUN([DX_FEATURE_xml],  [$1])])
renatofilho@320: AC_DEFUN([DX_PDF_FEATURE],     [AC_DEFUN([DX_FEATURE_pdf],  [$1])])
renatofilho@320: AC_DEFUN([DX_PS_FEATURE],      [AC_DEFUN([DX_FEATURE_ps],   [$1])])
renatofilho@320: 
renatofilho@320: # DX_INIT_DOXYGEN(PROJECT, [CONFIG-FILE], [OUTPUT-DOC-DIR])
renatofilho@320: # ---------------------------------------------------------
renatofilho@320: # PROJECT also serves as the base name for the documentation files.
renatofilho@320: # The default CONFIG-FILE is "Doxyfile" and OUTPUT-DOC-DIR is "doxygen-doc".
renatofilho@320: AC_DEFUN([DX_INIT_DOXYGEN], [
renatofilho@320: 
renatofilho@320: # Files:
renatofilho@320: AC_SUBST([DX_PROJECT], [$1])
renatofilho@320: AC_SUBST([DX_CONFIG], [ifelse([$2], [], Doxyfile, [$2])])
renatofilho@320: AC_SUBST([DX_DOCDIR], [ifelse([$3], [], doxygen-doc, [$3])])
renatofilho@320: 
renatofilho@320: # Environment variables used inside doxygen.cfg:
renatofilho@320: DX_ENV_APPEND(SRCDIR, $srcdir)
renatofilho@320: DX_ENV_APPEND(PROJECT, $DX_PROJECT)
renatofilho@320: DX_ENV_APPEND(DOCDIR, $DX_DOCDIR)
renatofilho@320: DX_ENV_APPEND(VERSION, $PACKAGE_VERSION)
renatofilho@320: 
renatofilho@320: # Doxygen itself:
renatofilho@320: DX_ARG_ABLE(doc, [generate any doxygen documentation],
renatofilho@320:             [],
renatofilho@320:             [],
renatofilho@320:             [DX_REQUIRE_PROG([DX_DOXYGEN], doxygen)
renatofilho@320:              DX_REQUIRE_PROG([DX_PERL], perl)],
renatofilho@320:             [DX_ENV_APPEND(PERL_PATH, $DX_PERL)])
renatofilho@320: 
renatofilho@320: # Dot for graphics:
renatofilho@320: DX_ARG_ABLE(dot, [generate graphics for doxygen documentation],
renatofilho@320:             [DX_CHECK_DEPEND(doc, 1)],
renatofilho@320:             [DX_CLEAR_DEPEND(doc, 1)],
renatofilho@320:             [DX_REQUIRE_PROG([DX_DOT], dot)],
renatofilho@320:             [DX_ENV_APPEND(HAVE_DOT, YES)
renatofilho@320:              DX_ENV_APPEND(DOT_PATH, [`DX_DIRNAME_EXPR($DX_DOT)`])],
renatofilho@320:             [DX_ENV_APPEND(HAVE_DOT, NO)])
renatofilho@320: 
renatofilho@320: # Man pages generation:
renatofilho@320: DX_ARG_ABLE(man, [generate doxygen manual pages],
renatofilho@320:             [DX_CHECK_DEPEND(doc, 1)],
renatofilho@320:             [DX_CLEAR_DEPEND(doc, 1)],
renatofilho@320:             [],
renatofilho@320:             [DX_ENV_APPEND(GENERATE_MAN, YES)],
renatofilho@320:             [DX_ENV_APPEND(GENERATE_MAN, NO)])
renatofilho@320: 
renatofilho@320: # RTF file generation:
renatofilho@320: DX_ARG_ABLE(rtf, [generate doxygen RTF documentation],
renatofilho@320:             [DX_CHECK_DEPEND(doc, 1)],
renatofilho@320:             [DX_CLEAR_DEPEND(doc, 1)],
renatofilho@320:             [],
renatofilho@320:             [DX_ENV_APPEND(GENERATE_RTF, YES)],
renatofilho@320:             [DX_ENV_APPEND(GENERATE_RTF, NO)])
renatofilho@320: 
renatofilho@320: # XML file generation:
renatofilho@320: DX_ARG_ABLE(xml, [generate doxygen XML documentation],
renatofilho@320:             [DX_CHECK_DEPEND(doc, 1)],
renatofilho@320:             [DX_CLEAR_DEPEND(doc, 1)],
renatofilho@320:             [],
renatofilho@320:             [DX_ENV_APPEND(GENERATE_XML, YES)],
renatofilho@320:             [DX_ENV_APPEND(GENERATE_XML, NO)])
renatofilho@320: 
renatofilho@320: # (Compressed) HTML help generation:
renatofilho@320: DX_ARG_ABLE(chm, [generate doxygen compressed HTML help documentation],
renatofilho@320:             [DX_CHECK_DEPEND(doc, 1)],
renatofilho@320:             [DX_CLEAR_DEPEND(doc, 1)],
renatofilho@320:             [DX_REQUIRE_PROG([DX_HHC], hhc)],
renatofilho@320:             [DX_ENV_APPEND(HHC_PATH, $DX_HHC)
renatofilho@320:              DX_ENV_APPEND(GENERATE_HTML, YES)
renatofilho@320:              DX_ENV_APPEND(GENERATE_HTMLHELP, YES)],
renatofilho@320:             [DX_ENV_APPEND(GENERATE_HTMLHELP, NO)])
renatofilho@320: 
renatofilho@320: # Seperate CHI file generation.
renatofilho@320: DX_ARG_ABLE(chi, [generate doxygen seperate compressed HTML help index file],
renatofilho@320:             [DX_CHECK_DEPEND(chm, 1)],
renatofilho@320:             [DX_CLEAR_DEPEND(chm, 1)],
renatofilho@320:             [],
renatofilho@320:             [DX_ENV_APPEND(GENERATE_CHI, YES)],
renatofilho@320:             [DX_ENV_APPEND(GENERATE_CHI, NO)])
renatofilho@320: 
renatofilho@320: # Plain HTML pages generation:
renatofilho@320: DX_ARG_ABLE(html, [generate doxygen plain HTML documentation],
renatofilho@320:             [DX_CHECK_DEPEND(doc, 1) DX_CHECK_DEPEND(chm, 0)],
renatofilho@320:             [DX_CLEAR_DEPEND(doc, 1) DX_CLEAR_DEPEND(chm, 0)],
renatofilho@320:             [],
renatofilho@320:             [DX_ENV_APPEND(GENERATE_HTML, YES)],
renatofilho@320:             [DX_TEST_FEATURE(chm) || DX_ENV_APPEND(GENERATE_HTML, NO)])
renatofilho@320: 
renatofilho@320: # PostScript file generation:
renatofilho@320: DX_ARG_ABLE(ps, [generate doxygen PostScript documentation],
renatofilho@320:             [DX_CHECK_DEPEND(doc, 1)],
renatofilho@320:             [DX_CLEAR_DEPEND(doc, 1)],
renatofilho@320:             [DX_REQUIRE_PROG([DX_LATEX], latex)
renatofilho@320:              DX_REQUIRE_PROG([DX_MAKEINDEX], makeindex)
renatofilho@320:              DX_REQUIRE_PROG([DX_DVIPS], dvips)
renatofilho@320:              DX_REQUIRE_PROG([DX_EGREP], egrep)])
renatofilho@320: 
renatofilho@320: # PDF file generation:
renatofilho@320: DX_ARG_ABLE(pdf, [generate doxygen PDF documentation],
renatofilho@320:             [DX_CHECK_DEPEND(doc, 1)],
renatofilho@320:             [DX_CLEAR_DEPEND(doc, 1)],
renatofilho@320:             [DX_REQUIRE_PROG([DX_PDFLATEX], pdflatex)
renatofilho@320:              DX_REQUIRE_PROG([DX_MAKEINDEX], makeindex)
renatofilho@320:              DX_REQUIRE_PROG([DX_EGREP], egrep)])
renatofilho@320: 
renatofilho@320: # LaTeX generation for PS and/or PDF:
renatofilho@320: if DX_TEST_FEATURE(ps) || DX_TEST_FEATURE(pdf); then
renatofilho@320:     AM_CONDITIONAL(DX_COND_latex, :)
renatofilho@320:     DX_ENV_APPEND(GENERATE_LATEX, YES)
renatofilho@320: else
renatofilho@320:     AM_CONDITIONAL(DX_COND_latex, false)
renatofilho@320:     DX_ENV_APPEND(GENERATE_LATEX, NO)
renatofilho@320: fi
renatofilho@320: 
renatofilho@320: # Paper size for PS and/or PDF:
renatofilho@320: AC_ARG_VAR(DOXYGEN_PAPER_SIZE,
renatofilho@320:            [a4wide (default), a4, letter, legal or executive])
renatofilho@320: case "$DOXYGEN_PAPER_SIZE" in
renatofilho@320: #(
renatofilho@320: "")
renatofilho@320:     AC_SUBST(DOXYGEN_PAPER_SIZE, "")
renatofilho@320: ;; #(
renatofilho@320: a4wide|a4|letter|legal|executive)
renatofilho@320:     DX_ENV_APPEND(PAPER_SIZE, $DOXYGEN_PAPER_SIZE)
renatofilho@320: ;; #(
renatofilho@320: *)
renatofilho@320:     AC_MSG_ERROR([unknown DOXYGEN_PAPER_SIZE='$DOXYGEN_PAPER_SIZE'])
renatofilho@320: ;;
renatofilho@320: esac
renatofilho@320: 
renatofilho@320: #For debugging:
renatofilho@320: #echo DX_FLAG_doc=$DX_FLAG_doc
renatofilho@320: #echo DX_FLAG_dot=$DX_FLAG_dot
renatofilho@320: #echo DX_FLAG_man=$DX_FLAG_man
renatofilho@320: #echo DX_FLAG_html=$DX_FLAG_html
renatofilho@320: #echo DX_FLAG_chm=$DX_FLAG_chm
renatofilho@320: #echo DX_FLAG_chi=$DX_FLAG_chi
renatofilho@320: #echo DX_FLAG_rtf=$DX_FLAG_rtf
renatofilho@320: #echo DX_FLAG_xml=$DX_FLAG_xml
renatofilho@320: #echo DX_FLAG_pdf=$DX_FLAG_pdf
renatofilho@320: #echo DX_FLAG_ps=$DX_FLAG_ps
renatofilho@320: #echo DX_ENV=$DX_ENV
renatofilho@320: ])