#                                               -*- Autoconf -*-

# Process this file with autoconf to produce a configure script.

AC_INIT([plover],[0.5.2.52],[ali@juiblex.co.uk])

AC_PREREQ(2.59)

AC_CONFIG_AUX_DIR([config])

AC_CONFIG_SRCDIR([plover/plover.h])

AC_CONFIG_HEADER([config.h])

AC_CONFIG_MACRO_DIR([m4])

AC_CONFIG_FILES([Makefile

plover/Makefile

plover/plover.pc

plover-gtk/Makefile

plover-gtk/plover-gtk.pc

setup/Makefile

setup/resources.rc

update/Makefile

update/resources.rc

pre-inst/Makefile

pre-inst/resources.rc

app-manager/Makefile

app-manager/resources.rc

plover-open/Makefile

plover-open/resources.rc

tests/Makefile

tests/plover/Makefile

tests/plover-gtk/Makefile

])

PLOVER_MSWIN_MANIFEST([setup/setup.exe.manifest:setup/manifest.xml.in

update/update.exe.manifest:update/manifest.xml.in

pre-inst/pre-inst.exe.manifest:pre-inst/manifest.xml.in

app-manager/app-manager.exe.manifest:app-manager/manifest.xml.in

plover-open/plover-open.exe.manifest:plover-open/manifest.xml.in

])

AM_INIT_AUTOMAKE(no-define parallel-tests)

m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])

case $VERSION in

  *.*.*)

    AC_SUBST(PLOVER_MAJOR_VERSION,[[`echo $VERSION | sed 's/\..*//'`]])

    AC_SUBST(PLOVER_MINOR_VERSION,

      [[`echo $VERSION | sed 's/[^.]*\.\([^.]*\)\..*/\1/'`]])

    AC_SUBST(PLOVER_MICRO_VERSION,[[`echo $VERSION | sed 's/.*\.\([^.]*\)/\1/'`]])      ;;

  *.*)

    AC_SUBST(PLOVER_MAJOR_VERSION,[[`echo $VERSION | sed 's/\..*//'`]])

    AC_SUBST(PLOVER_MINOR_VERSION,

      [[`echo $VERSION | sed 's/[^.]*\.\([^.]*\)/\1/'`]])

    AC_SUBST(PLOVER_MICRO_VERSION,0)

    ;;

  *)

    AC_SUBST(PLOVER_MAJOR_VERSION,0)

    AC_SUBST(PLOVER_MINOR_VERSION,0)

    AC_SUBST(PLOVER_MICRO_VERSION,0)

    ;;

esac

AC_CANONICAL_HOST

AC_SUBST(HOST_OS,$host_os)

AC_SUBST(HOST_CPU,$host_cpu)

case $host_os in

    mingw*)

	host_mingw="yes"

	;;

    *)

	host_mingw=""

	;;

esac

AM_CONDITIONAL(PLOVER_MINGW,[test -n "$host_mingw"])

# libtool versioning for libplover. For a release one of the following

# must apply:

#

# - If interfaces have been changed or added, but binary compatibility has

#   been preserved, increment CURRENT and AGE and set REVISION to 0.

# - If binary compatibility has been broken (eg removed or changed interfaces),

#   increment CURRENT and set AGE and REVISION to 0.

# - If the interface is the same as the previous version, increment REVISION.

#

lt_current=4

lt_revision=1

lt_age=1

LIBPLOVER_LT_VERSION_INFO="$lt_current:$lt_revision:$lt_age"

AC_SUBST(LIBPLOVER_LT_VERSION_INFO)

# and likewise for plover-gtk.

#

lt_current=1

lt_revision=1

lt_age=0

PLOVER_GTK_LT_VERSION_INFO="$lt_current:$lt_revision:$lt_age"

AC_SUBST(PLOVER_GTK_LT_VERSION_INFO)

##################################################

# Checks for programs.

##################################################

AC_PROG_CC

AC_PROG_CXX

AC_LIBTOOL_WIN32_DLL

AC_PROG_LIBTOOL

PKG_PROG_PKG_CONFIG

AC_CHECK_TOOL([WINDRES],[windres],[no])

AM_CONDITIONAL([HAVE_WINDRES],[test x$WINDRES != xno])

AC_CHECK_PROGS([RSVG],[rsvg rsvg-convert],[no])

if test "$RSVG" = no; then

    AC_MSG_ERROR([no rsvg program found to convert SVG files to bitmaps])

fi

AX_VALGRIND_CHECK

AS_IF([test "$enable_valgrind" != "no"],[[

    major=`$VALGRIND --version | \

      sed -e 's/^valgrind-//' -e 's/^[^.]*$/0/' -e 's/\..*//'`

    minor=`$VALGRIND --version | \

      sed -e 's/^valgrind-//' -e 's/.*/&.0.0/' -e 's/[^.]*\.\([^.]*\)\..*/\1/'`

]],[major=0; minor=0])

AM_CONDITIONAL([HAVE_VALGRIND_3_9],[test 0$major -gt 3 -o 0$minor -gt 8])

AX_CODE_COVERAGE

AC_CHECK_TOOL([RAZOR],[razor],[no])

AC_CHECK_TOOL([RPMBUILD],[rpmbuild],[no])

AC_CHECK_TOOL([CREATEREPO],[createrepo],[no])

AC_CHECK_TOOL([COMPILE_RESOURCES],[glib-compile-resources],[no])

AM_CONDITIONAL([HAVE_CHECK_TOOLS],

  [test x$RAZOR != xno -a x$RPMBUILD != xno -a x$CREATEREPO != xno -a \

   x$COMPILE_RESOURCES != xno])

##################################################

# Checks for header files.

##################################################

AC_HEADER_STDC

AC_CHECK_HEADERS([winhttp.h],[],[],

[#include <windows.h>

])

##################################################

# Checks for typedefs, structures, and compiler characteristics.

##################################################

##################################################

# Checks for libraries.

##################################################

PKG_CHECK_MODULES(WHELK,[whelk])

PKG_CHECK_MODULES(RAZOR,[razor >= 0.5.4],[:],[RAZOR_LIBS=-lrazor])

PKG_CHECK_MODULES(EXPAT,[expat >= 2.1],[:],

  [PKG_CHECK_MODULES(EXPAT,[expat21],[:],[EXPAT_LIBS=-lexpat])])

PKG_CHECK_MODULES(ZLIB,[zlib],[:],[ZLIB_LIBS=-lz])

PKG_CHECK_MODULES(LUA,[lua],[:],[LUA_LIBS=-llua])

PKG_CHECK_MODULES(GIO,[gio-2.0])

PKG_CHECK_MODULES(GTK,[gtk+-2.0])

PKG_CHECK_MODULES(GMODULE_EXPORT,[gmodule-export-2.0])

LIBPLOVER_CFLAGS="$RAZOR_CFLAGS $EXPAT_CFLAGS $ZLIB_CFLAGS $GIO_CFLAGS"

LIBPLOVER_LIBS="$RAZOR_LIBS $EXPAT_LIBS $ZLIB_LIBS $GIO_LIBS"

AC_SUBST(LIBPLOVER_CFLAGS)

AC_SUBST(LIBPLOVER_LIBS)

PLOVER_GTK_CFLAGS="$GTK_CFLAGS $RAZOR_CFLAGS"

PLOVER_GTK_LIBS="$GTK_LIBS $RAZOR_LIBS"

AC_SUBST(PLOVER_GTK_CFLAGS)

AC_SUBST(PLOVER_GTK_LIBS)

save_LIBS="$LIBS"

AC_SEARCH_LIBS([crypt],[crypt])

LUA_POSIX_CFLAGS="$LUA_CFLAGS"

LUA_POSIX_LIBS="-llua-posix $LUA_LIBS $LIBS"

LIBS="$save_LIBS"

AC_SUBST(LUA_POSIX_CFLAGS)

AC_SUBST(LUA_POSIX_LIBS)

GUI_CFLAGS="$GMODULE_EXPORT_CFLAGS $WHELK_CFLAGS $PLOVER_GTK_CFLAGS \

  $LIBPLOVER_CFLAGS $LUA_POSIX_CFLAGS"

GUI_LIBS="$GMODULE_EXPORT_LIBS $WHELK_LIBS $PLOVER_GTK_LIBS \

  $LIBPLOVER_LIBS $LUA_POSIX_LIBS"

AC_SUBST(GUI_CFLAGS)

AC_SUBST(GUI_LIBS)

save_PKG_CONFIG="$PKG_CONFIG"

PKG_CONFIG="$PKG_CONFIG --static"

PKG_CHECK_MODULES(SETUP,[whelk razor >= 0.5.4 expat >= 2.1 zlib gio-2.0],[:],

  [PKG_CHECK_MODULES(SETUP,[whelk razor >= 0.5.4 expat21 zlib gio-2.0])])

if test -n "$host_mingw"; then

    # Hacks:

    # -liconv is required for mingw. This probably stems from our use of

    # libiconv rather than win-iconv that Fedora uses, but should be addressed

    # somewhere in the stack below us.

    # -ldnsapi is required by gio. This probably represents a gio bug.

    SETUP_LIBS="$SETUP_LIBS -liconv -ldnsapi"

fi

PKG_CONFIG="$save_PKG_CONFIG"

SETUP_CFLAGS="$SETUP_CFLAGS $LUA_POSIX_CFLAGS"

SETUP_LIBS="$SETUP_LIBS $LUA_POSIX_LIBS"

AC_SUBST(SETUP_LIBS)

AC_SUBST(SETUP_CFLAGS)

save_LIBS="$LIBS"

LIBS="$LIBS -lcrypt32"

AC_MSG_CHECKING([for library containing CertEnumCertificatesInStore])

AC_LINK_IFELSE([AC_LANG_PROGRAM(

  [[#include <windows.h>]],

  [return !CertEnumCertificatesInStore((HCERTSTORE)0,NULL);])],

  [FETCH_LIBS="-lcrypt32"])

if test -z "$FETCH_LIBS"; then

    AC_MSG_RESULT([no])

else

    AC_MSG_RESULT([$FETCH_LIBS])

fi

AC_SUBST([FETCH_LIBS])

LIBS="$save_LIBS"

AC_ARG_WITH([breakpad],

  [AS_HELP_STRING([--with-breakpad],

    [produce minidumps on crash @<:@default=check@:>@])],

  [],[with_breakpad=check])

if test "$with_breakpad" != no; then

    PKG_CHECK_MODULES([BREAKPAD],[breakpad-client],

      [have_breakpad="yes";REQUIREMENTS="$REQUIREMENTS x11"],[have_breakpad="no"])

    if test "$have_breakpad" = yes; then

	AC_DEFINE([HAVE_BREAKPAD],[1],[Define if breakpad is available.])

    elif test "$with_breakpad" = yes; then

	AC_MSG_ERROR([$BREAKPAD_PKG_ERRORS])

    fi

else

    have_breakpad="no"

fi

AM_CONDITIONAL([HAVE_BREAKPAD],[test $have_breakpad = yes])

##################################################

# Checks for library functions.

##################################################

AC_CHECK_FUNCS_ONCE([fchdir fpathconf dirfd localtime_r])

##################################################

# Checks for processor independent files.

##################################################

##################################################

# Generate the various configured files

##################################################

AC_OUTPUT