#                                               -*- Autoconf -*-

 # Process this file with autoconf to produce a configure script.

 AC_INIT([plover],[0.5],[ali@juiblex.co.uk])

 AC_PREREQ(2.59)

 AC_CONFIG_AUX_DIR([config])

 AC_CONFIG_SRCDIR([plover/plover.h])

 AC_CONFIG_HEADER([config.h])

 AC_CONFIG_FILES([Makefile

 plover/Makefile

 plover/plover.pc

 plover-gtk/Makefile

 plover-gtk/plover-gtk.pc

 setup/Makefile

 setup/resources.rc

 update/Makefile

 update/resources.rc

 pre-inst/Makefile

 pre-inst/resources.rc

 app-manager/Makefile

 app-manager/resources.rc

 plover-open/Makefile

 plover-open/resources.rc

 ])

 PLOVER_MSWIN_MANIFEST([setup/setup.exe.manifest:setup/manifest.xml.in

 update/update.exe.manifest:update/manifest.xml.in

 pre-inst/pre-inst.exe.manifest:pre-inst/manifest.xml.in

 app-manager/app-manager.exe.manifest:app-manager/manifest.xml.in

 plover-open/plover-open.exe.manifest:plover-open/manifest.xml.in

 ])

 AM_INIT_AUTOMAKE(no-define)

 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])

 case $VERSION in

   *.*.*)

     AC_SUBST(PLOVER_MAJOR_VERSION,[[`echo $VERSION | sed 's/\..*//'`]])

     AC_SUBST(PLOVER_MINOR_VERSION,

       [[`echo $VERSION | sed 's/[^.]*\.\([^.]*\)\..*/\1/'`]])

     AC_SUBST(PLOVER_MICRO_VERSION,[[`echo $VERSION | sed 's/.*\.\([^.]*\)/\1/'`]])      ;;

   *.*)

     AC_SUBST(PLOVER_MAJOR_VERSION,[[`echo $VERSION | sed 's/\..*//'`]])

     AC_SUBST(PLOVER_MINOR_VERSION,

       [[`echo $VERSION | sed 's/[^.]*\.\([^.]*\)/\1/'`]])

     AC_SUBST(PLOVER_MICRO_VERSION,0)

     ;;

   *)

     AC_SUBST(PLOVER_MAJOR_VERSION,0)

     AC_SUBST(PLOVER_MINOR_VERSION,0)

     AC_SUBST(PLOVER_MICRO_VERSION,0)

     ;;

 esac

 AC_CANONICAL_HOST

 AC_SUBST(HOST_OS,$host_os)

 AC_SUBST(HOST_CPU,$host_cpu)

 case $host_os in

     mingw*)

 	host_mingw="yes"

 	;;

     *)

 	host_mingw=""

 	;;

 esac

 AM_CONDITIONAL(PLOVER_MINGW,[test -n "$host_mingw"])

 # libtool versioning for libplover. For a release one of the following

 # must apply:

 #

 # - If interfaces have been changed or added, but binary compatibility has

 #   been preserved, increment CURRENT and AGE and set REVISION to 0.

 # - If binary compatibility has been broken (eg removed or changed interfaces),

 #   increment CURRENT and set AGE and REVISION to 0.

 # - If the interface is the same as the previous version, increment REVISION.

 #

 lt_current=3

 lt_revision=0

 lt_age=0

 LIBPLOVER_LT_VERSION_INFO="$lt_current:$lt_revision:$lt_age"

 AC_SUBST(LIBPLOVER_LT_VERSION_INFO)

 # and likewise for plover-gtk.

 #

 lt_current=1

 lt_revision=0

 lt_age=0

 PLOVER_GTK_LT_VERSION_INFO="$lt_current:$lt_revision:$lt_age"

 AC_SUBST(PLOVER_GTK_LT_VERSION_INFO)

 ##################################################

 # Checks for programs.

 ##################################################

 AC_PROG_CC

 AC_LIBTOOL_WIN32_DLL

 AC_PROG_LIBTOOL

 PKG_PROG_PKG_CONFIG

 AC_CHECK_TOOL(WINDRES,windres,no)

 AM_CONDITIONAL([HAVE_WINDRES],[test x$WINDRES != xno])

 ##################################################

 # Checks for header files.

 ##################################################

 AC_HEADER_STDC

 AC_CHECK_HEADERS([winhttp.h],[],[],

 [#include <windows.h>

 ])

 ##################################################

 # Checks for typedefs, structures, and compiler characteristics.

 ##################################################

 ##################################################

 # Checks for libraries.

 ##################################################

 PKG_CHECK_MODULES(WHELK,[whelk])

 PKG_CHECK_MODULES(RAZOR,[razor >= 0.5.4],[:],[RAZOR_LIBS=-lrazor])

 PKG_CHECK_MODULES(EXPAT,[expat],[:],[EXPAT_LIBS=-lexpat])

 PKG_CHECK_MODULES(ZLIB,[zlib],[:],[ZLIB_LIBS=-lz])

 PKG_CHECK_MODULES(GIO,[gio-2.0])

 PKG_CHECK_MODULES(GTK,[gtk+-2.0])

 PKG_CHECK_MODULES(GMODULE_EXPORT,[gmodule-export-2.0])

 LIBPLOVER_CFLAGS="$RAZOR_CFLAGS $EXPAT_CFLAGS $ZLIB_CFLAGS $GIO_CFLAGS"

 LIBPLOVER_LIBS="$RAZOR_LIBS $EXPAT_LIBS $ZLIB_LIBS $GIO_LIBS"

 AC_SUBST(LIBPLOVER_CFLAGS)

 AC_SUBST(LIBPLOVER_LIBS)

 PLOVER_GTK_CFLAGS="$GTK_CFLAGS $RAZOR_CFLAGS"

 PLOVER_GTK_LIBS="$GTK_LIBS $RAZOR_LIBS"

 AC_SUBST(PLOVER_GTK_CFLAGS)

 AC_SUBST(PLOVER_GTK_LIBS)

 save_LIBS="$LIBS"

 AC_SEARCH_LIBS([crypt],[crypt])

 GUI_CFLAGS="$GMODULE_EXPORT_CFLAGS $WHELK_CFLAGS $PLOVER_GTK_CFLAGS \

   $LIBPLOVER_CFLAGS"

 GUI_LIBS="-llua-posix $GMODULE_EXPORT_LIBS $WHELK_LIBS $PLOVER_GTK_LIBS \

   $LIBPLOVER_LIBS $LIBS"

 LIBS="$save_LIBS"

 AC_SUBST(GUI_CFLAGS)

 AC_SUBST(GUI_LIBS)

 save_PKG_CONFIG="$PKG_CONFIG"

 PKG_CONFIG="$PKG_CONFIG --static"

 PKG_CHECK_MODULES(SETUP,[whelk razor >= 0.5.4 expat zlib gio-2.0])

 if test -n "$host_mingw"; then

     # Hack: -liconv is required for mingw. This probably stems from our use of

     # libiconv rather than win-iconv that Fedora uses, but should be addressed

     # somewhere in the stack below us.

     SETUP_LIBS="$SETUP_LIBS -liconv"

 fi

 PKG_CONFIG="$save_PKG_CONFIG"

 save_LIBS="$LIBS"

 AC_SEARCH_LIBS([crypt],[crypt])

 SETUP_LIBS="-llua-posix $SETUP_LIBS $LIBS"

 SETUP_CFLAGS="$SETUP_CFLAGS"

 AC_SUBST(SETUP_LIBS)

 AC_SUBST(SETUP_CFLAGS)

 LIBS="$save_LIBS"

 LIBS="$LIBS -lcrypt32"

 AC_MSG_CHECKING([for library containing CertEnumCertificatesInStore])

 AC_LINK_IFELSE([AC_LANG_PROGRAM(

   [[#include <windows.h>]],

   [return !CertEnumCertificatesInStore((HCERTSTORE)0,NULL);])],

   [FETCH_LIBS="-lcrypt32"])

 if test -z "$FETCH_LIBS"; then

     AC_MSG_RESULT([no])

 else

     AC_MSG_RESULT([$FETCH_LIBS])

 fi

 AC_SUBST([FETCH_LIBS])

 LIBS="$save_LIBS"

 ##################################################

 # Checks for library functions.

 ##################################################

 AC_CHECK_FUNCS_ONCE([fchdir fpathconf dirfd])

 ##################################################

 # Checks for processor independent files.

 ##################################################

 ##################################################

 # Generate the various configured files

 ##################################################

 AC_OUTPUT