dnl Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59c)

AC_INIT([razor], [0.6.3.112], [ali@juiblex.co.uk])

AM_INIT_AUTOMAKE([])

AM_CONFIG_HEADER([config.h])

AM_MAINTAINER_MODE

# libtool versioning - this applies to all libraries in this package

#

# See https://www.sourceware.org/autobook/autobook/autobook_61.html for details

#

LT_CURRENT=6

LT_REVISION=0

LT_AGE=0

AC_SUBST(LT_CURRENT)

AC_SUBST(LT_REVISION)

AC_SUBST(LT_AGE)

AC_ISC_POSIX

AC_PROG_CC

gl_EARLY

AM_PROG_CC_STDC

AC_HEADER_STDC

AC_HEADER_SYS_WAIT

AC_CHECK_HEADERS([sys/mman.h])

gl_INIT

AC_CHECK_FUNCS([symlink chroot])

LT_INIT([win32-dll])

# Libtool supports a --disable-shared option to tell it to avoid

# building shared versions of libraries. In addition to this,we want

# to support building static versions of our executables. Libtool

# can do this (under the right circumstances) so we overload this

# switch for this purpose.

#

# The libtool option that we use (-static-libtool-libs) means to use

# static linking with libraries that supply a .la file and which

# include a non-empty value for "old_library". If the library doesn't

# include a .la file (they are deleted by some distributions), then

# this option will have no effect and likewise if old_library is set

# to '' (eg., if the library was build with --disable-static) then

# again -static-libtool-libs will have no effect.

#

# If old_library is set to a non-empty value, then specifying

# -static-libtool-libs will cause the link to fail if the old library

# cannot be found (libtool will not fallback to a shared library

# in these circumstances). This can happen with Fedora, for example,

# if a main mingw32 library package is installed but not the

# coresponding static sub-package. The solution is to either

# install the relevant static sub-packages or don't use --disable-shared.

AS_IF([test "$enable_shared" = no],[

  LDFLAGS="$LDFLAGS -static-libtool-libs"

])

LT_OUTPUT

ac_compile="./libtool --mode=compile --tag=CC $ac_compile"

ac_link="./libtool --mode=link --tag=CC $ac_link"

AC_PROG_MAKE_SET

AC_PROG_LN_S

AC_SYS_LARGEFILE

AM_PROG_CC_C_O

AC_ARG_ENABLE([atomic],

	      [AS_HELP_STRING([--disable-atomic],

	      		      [disable atomic transactions])],

	      [],

	      [enable_atomic=yes])

if test "$enable_atomic" = "yes"; then

    AC_DEFINE([ENABLE_ATOMIC],[1],[Define if atomic transactions are wanted.])

    AC_SUBST([RAZOR_HAVE_ATOMIC_ROLLBACK],

      ['#define RAZOR_HAVE_ATOMIC_ROLLBACK 1'])

else

    AC_SUBST([RAZOR_HAVE_ATOMIC_ROLLBACK],['#undef RAZOR_HAVE_ATOMIC_ROLLBACK'])

fi

AC_ARG_ENABLE([tests],

	      [AS_HELP_STRING([--enable-tests],

	      		      [install test programs])],

	      [],

	      [enable_tests=no])

AM_CONDITIONAL(INSTALL_TEST_PROGRAMS, test "$enable_tests" = "yes")

AC_MSG_CHECKING([for Microsoft Windows native API])

case $host_os in

    *mingw*)	AC_DEFINE([MSWIN_API], 1,

		  [Define to 1 to use Microsoft Windows native API.])

		EXTRA_LIBS='-lshlwapi -lshell32 -lws2_32 -lole32'

		mswin_api=yes;;

    *)		mswin_api=no;;

esac

AC_MSG_RESULT([$mswin_api])

AM_CONDITIONAL(MSWIN_API, test "$mswin_api" = "yes")

AC_SUBST(EXTRA_LIBS)

if test "$enable_atomic" = "yes" -a "$mswin_api" = "yes"; then

    AC_MSG_CHECKING([for Microsoft Windows Kernel Transaction Manager])

    save_LIBS="$LIBS"

    LIBS="-lktmw32 $LIBS"

    AC_LINK_IFELSE([AC_LANG_PROGRAM([dnl

#include <windows.h>

#include <ktmw32.h>

], [(void)CreateTransaction(NULL,0,0,0,0,0,NULL);])],

      [have_windows_ktm="yes"; EXTRA_LIBS="-lktmw32 $EXTRA_LIBS"],

      [have_windows_ktm="no"])

    LIBS="$save_LIBS"

    AC_MSG_RESULT([$have_windows_ktm])

else

    have_windows_ktm="no"

fi

if test "$have_windows_ktm" = "yes"; then

    AC_DEFINE([HAVE_WINDOWS_KTM],[1],[Define if Windows KTM is available.])

fi

# Taken from dbus

AC_ARG_ENABLE(ansi,             [  --enable-ansi           enable -ansi -pedantic gcc flags],enable_ansi=$enableval,enable_ansi=no)

AC_ARG_ENABLE(verbose-mode,     [  --enable-verbose-mode   support verbose debug mode],enable_verbose_mode=$enableval,enable_verbose_mode=$USE_MAINTAINER_MODE)

if test "${enable_verbose_mode}" != no; then

    # To get -rdynamic you pass -export-dynamic to libtool.

    AC_DEFINE(BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])

    R_DYNAMIC_LDFLAG=-export-dynamic

else

    R_DYNAMIC_LDFLAG=

fi

AC_SUBST(R_DYNAMIC_LDFLAG)

#### gcc warning flags

if test "x$GCC" = "xyes"; then

  changequote(,)dnl

  case " $CFLAGS " in

  *[\ \	]-Wall[\ \	]*) ;;

  *) CFLAGS="$CFLAGS -Wall -Wno-parentheses" ;;

  esac

  case " $CFLAGS " in

  *[\ \	]-Wchar-subscripts[\ \	]*) ;;

  *) CFLAGS="$CFLAGS -Wchar-subscripts" ;;

  esac

  case " $CFLAGS " in

  *[\ \	]-Wmissing-declarations[\ \	]*) ;;

  *) CFLAGS="$CFLAGS -Wmissing-declarations" ;;

  esac

  case " $CFLAGS " in

  *[\ \	]-Wnested-externs[\ \	]*) ;;

  *) CFLAGS="$CFLAGS -Wnested-externs" ;;

  esac

  case " $CFLAGS " in

  *[\ \	]-Wcast-align[\ \	]*) ;;

  *) CFLAGS="$CFLAGS -Wcast-align" ;;

  esac

  case " $CFLAGS " in

  *[\ \	]-Wformat[\ \	]*) ;;

  *) CFLAGS="$CFLAGS -Wformat" ;;

  esac

  case " $CFLAGS " in

  *[\ \	]-Wformat-security[\ \	]*) ;;

  *) CFLAGS="$CFLAGS -Wformat-security" ;;

  esac

  if test "x$enable_ansi" = "xyes"; then

    case " $CFLAGS " in

    *[\ \	]-ansi[\ \	]*) ;;

    *) CFLAGS="$CFLAGS -ansi" ;;

    esac

    case " $CFLAGS " in

    *[\ \	]-D_POSIX_C_SOURCE*) ;;

    *) CFLAGS="$CFLAGS -D_POSIX_C_SOURCE=199309L" ;;

    esac

    case " $CFLAGS " in

    *[\ \	]-D_BSD_SOURCE[\ \	]*) ;;

    *) CFLAGS="$CFLAGS -D_BSD_SOURCE" ;;

    esac

    case " $CFLAGS " in

    *[\ \	]-pedantic[\ \	]*) ;;

    *) CFLAGS="$CFLAGS -pedantic" ;;

    esac

  fi

  changequote([,])dnl

fi

# gcc default visibility stuff

have_gcc4=no

AC_MSG_CHECKING(for -fvisibility)

AC_COMPILE_IFELSE([

#if defined(__GNUC__) && (__GNUC__ >= 4)

#else

#error Need GCC 4.0 for visibility

#endif

int main () { return 0; } 

], have_gcc4=yes)

if test "x$have_gcc4" = "xyes"; then

   CFLAGS="$CFLAGS -fvisibility=hidden"

fi

AC_MSG_RESULT($have_gcc4)

REQUIREMENTS=""

AC_ARG_WITH([libarchive],

            [AS_HELP_STRING([--without-libarchive],

	        [disable support for libarchive])],

            [],

            [with_libarchive=yes])

LIBARCHIVE_CFLAGS=

LIBARCHIVE_LIBS=

AS_IF([test "x$with_libarchive" != xno],

  [PKG_CHECK_MODULES(LIBARCHIVE, [libarchive])

   REQUIREMENTS="$REQUIREMENTS libarchive"

   AC_DEFINE([HAVE_LIBARCHIVE], [1], [Define if you have libarchive])])

AC_SUBST(LIBARCHIVE_CFLAGS)

AC_SUBST(LIBARCHIVE_LIBS)

AS_IF([test "x$with_libarchive" != xno],

   [AC_PATH_PROG(ZIP, [zip], [])])

AM_CONDITIONAL([HAVE_ZIP], [test -n "$ZIP"])

AC_ARG_WITH([curl],

            [AS_HELP_STRING([--without-curl], [disable support for curl])],

            [],

            [with_curl=yes])

CURL_CFLAGS=

CURL_LIBS=

AS_IF([test "x$with_curl" != xno],

  [PKG_CHECK_MODULES(CURL, [libcurl])

   AC_DEFINE([HAVE_CURL], [1], [Define if you have curl])])

AC_SUBST(CURL_CFLAGS)

AC_SUBST(CURL_LIBS)

AM_CONDITIONAL([HAVE_CURL], [test "x$with_curl" != xno])

ZLIB_LIBS=""

AC_ARG_WITH(zlib, [  --with-zlib=<dir>       Use zlib from here],

                      [

                      zlib=$withval

                      CPPFLAGS="$CPPFLAGS -I$withval/include"

                      ]

                      )

AC_CHECK_HEADERS(zlib.h, [AC_DEFINE(HAVE_ZLIB_H)],

                 [AC_MSG_ERROR([Can't find zlib.h. Please install zlib.])])

save_ldflags="$LDFLAGS"

LDFLAGS="$LDFLAGS -L$zlib/lib"

AC_CHECK_LIB(z, inflate, [ZLIB_LIBS="-L$zlib/lib -lz"],

	     [AC_MSG_ERROR([Can't find zlib library. Please install zlib.])])

LDFLAGS="$save_ldflags"

AC_SUBST(ZLIB_LIBS)

EXPAT_LIB=""

PKG_CHECK_MODULES(EXPAT, [expat22],

  [AC_DEFINE([HAVE_EXPAT_H])

   CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"],

  [AC_ARG_WITH(expat, [  --with-expat=<dir>      If expat 2.2 isn't available,

                          fallback to using legacy expat from here],

                        [

                        expat=$withval

                        CPPFLAGS="$CPPFLAGS -I$withval/include"

                        ]

                        )

  AC_CHECK_HEADERS(expat.h, [AC_DEFINE(HAVE_EXPAT_H)], 

		 [AC_MSG_ERROR([Can't find expat.h. Please install expat.])])

  save_ldflags="$LDFLAGS"

  LDFLAGS="$LDFLAGS -L$expat/lib"

  AC_CHECK_LIB(expat, XML_ParserCreate, [EXPAT_LIBS="-L$expat/lib -lexpat"],

	     [AC_MSG_ERROR([Can't find expat library. Please install expat.])])

  LDFLAGS="$save_ldflags"])

AC_SUBST(EXPAT_LIBS)

RPM_LIBS=""

AC_ARG_WITH(rpm, [  --with-rpm=<dir>      Use rpm from here])

AS_IF([test "$with_rpm" != no],

      [if test "$with_rpm" != yes; then

	    CPPFLAGS="$CPPFLAGS -I$with_rpm/include"

       fi

       AC_CHECK_HEADERS(rpm/rpmlib.h, [], 

		 [AC_MSG_ERROR([Can't find rpm/rpmlib.h. Please install rpm-devel or use --without-rpm.])])

       save_ldflags="$LDFLAGS"

       LDFLAGS="$LDFLAGS -L$with_rpm/lib"

       AC_CHECK_LIB(rpm,rpmdbOpen,[RPM_LIBS="-L$with_rpm/lib -lrpm"],

	     [AC_MSG_ERROR([Can't find rpm library. Please install rpm-devel or use --without-rpm.])])

       LDFLAGS="$save_ldflags"

       AC_DEFINE([HAVE_RPMLIB], [1], [Define if you have librpm])])

AC_SUBST(RPM_LIBS)

AM_CONDITIONAL([HAVE_RPMLIB], [test -n "$RPM_LIBS"])

AC_ARG_WITH([lua],

            [AS_HELP_STRING([--without-lua], [disable support for lua])],

            [],

            [with_lua=yes])

AS_IF([test "x$with_lua" != xno],

  [PKG_CHECK_MODULES(LUA, [lua])

   REQUIREMENTS="$REQUIREMENTS lua"

   AC_DEFINE([HAVE_LUA], [1], [Define if you have lua])

   AC_PATH_PROG(LUA, [lua], [no])

   AS_IF([test "x$LUA" = xno],

     [AC_MSG_ERROR([Can't find lua program. Please install lua-devel or use --without-lua.])])

   AC_DEFINE_UNQUOTED([LUA_BINARY], ["$LUA"],

     [Define to the location of the lua binary])])

AC_SUBST(LUA_CFLAGS)

AC_SUBST(LUA_LIBS)

AM_CONDITIONAL([HAVE_LUA], [test "x$with_lua" != xno])

AC_SUBST(REQUIREMENTS)

if test "x$GCC" = "xyes"; then

  LDFLAGS="-Wl,--as-needed $LDFLAGS"

fi

# *****************************

# Make available to Makefile.am

# *****************************

AC_SUBST(SYSCONFDIR, $sysconfdir)

# ********************

# Internationalisation

# ********************

IT_PROG_INTLTOOL([0.35.0])

GETTEXT_PACKAGE=razor

AC_SUBST([GETTEXT_PACKAGE])

AM_GLIB_GNU_GETTEXT

AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[gettext domain])

GTK_DOC_CHECK([1.9])

AC_OUTPUT([

Makefile

data/razor.pc

data/Makefile

librazor/Makefile

librazor/razor.h

librazor/types/Makefile

src/Makefile

docs/Makefile

docs/version.xml

po/Makefile.in

gl/Makefile

test/Makefile

])

dnl ==========================================================================

echo "

                  razor $VERSION

                =================

        prefix:                     ${prefix}

        libdir:                     ${libdir}

        libexecdir:                 ${libexecdir}

        bindir:                     ${bindir}

        sbindir:                    ${sbindir}

        datadir:                    ${datadir}

        sysconfdir:                 ${sysconfdir}

        localstatedir:              ${localstatedir}

        docdir:                     ${docdir}

        compiler:                   ${CC}

        cflags:                     ${CFLAGS}

        Maintainer mode:            ${USE_MAINTAINER_MODE}

        Building verbose mode:      ${enable_verbose_mode}

        Building gtk-doc:           ${enable_gtk_doc}

"