<?xml version="1.0"?>

 <!-- This stylesheet extracts some details of attachments from the artifact

      history of a sourceforge project export. -->

 <xsl:stylesheet version="1.0"

 		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"

 		xmlns:xi="http://www.w3.org/2001/XInclude">

 <xsl:import href="sf2bz.xsl"/>

 <!-- Process a sourceforge artifact, outputting attachments as found -->

 <xsl:template name="process-artifact">

     <xsl:apply-templates/>

     <xsl:for-each

       select="field[@name='artifact_history']/history[field[@name='field_name']='File Added']">

       <xsl:variable name="file_id"

         select="substring-before(field[@name='old_value'],':')"/>

       <attachment>

 	<!-- isobsolete is an attribute of bugzilla:attachment, but that

 	     proves hard to deal with so we treat it as a node and fix it

 	     up in attachment_post.xsl -->

 	<isobsolete>

 	  <xsl:value-of select="number(boolean(../history[field[@name='field_name']='File Deleted' and substring-before(field[@name='old_value'],':')=$file_id]))"/>

 	</isobsolete>

 	<attachid>

 	  <xsl:value-of select="$file_id"/>

 	</attachid>

 	<date>

 	  <xsl:call-template name="bugzilla-timestamp">

 	    <xsl:with-param name="secs" select="field[@name='entrydate']"/>

 	  </xsl:call-template>

 	</date>

 	<filename>

 	  <xsl:value-of

 	    select="substring-after(field[@name='old_value'],': ')"/>

 	</filename>

       </attachment>

     </xsl:for-each>

 </xsl:template>

 <xsl:template match="project_export">

   <attachments>

     <xsl:apply-templates/>

   </attachments>

 </xsl:template>

 <xsl:template match="artifacts">

   <xsl:apply-templates/>

 </xsl:template>

 <xsl:template match="artifact">

   <xsl:variable name="type"

     select="normalize-space(field[@name='artifact_type'])"/>

   <xsl:choose>

     <xsl:when test="$type = 'Feature Requests'">

       <xsl:call-template name="process-artifact"/>

     </xsl:when>

     <xsl:when test="$type = 'Patches'">

       <xsl:call-template name="process-artifact"/>

     </xsl:when>

     <xsl:when test="$type = 'Bugs'">

       <xsl:call-template name="process-artifact"/>

     </xsl:when>

   </xsl:choose>

 </xsl:template>

 <xsl:template match="node()|text()" priority="-1"></xsl:template>

 </xsl:stylesheet>