<?xml version="1.0"?>

 <xsl:stylesheet version="1.0"

 		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"

 		xmlns:exsl="http://exslt.org/common"

 		extension-element-prefixes="exsl">

 <xsl:variable name="users">

   <xsl:for-each select="//artifact/field[@name='submitted_by' or @name='assigned_to']">

     <user><xsl:value-of select="normalize-space(.)"/></user>

   </xsl:for-each>

   <xsl:for-each select="//artifact/field[@name='artifact_history']/history/field[@name='mod_by']">

     <user><xsl:value-of select="normalize-space(.)"/></user>

   </xsl:for-each>

   <xsl:for-each select="//artifact/field[@name='artifact_messages']/message/field[@name='user_name']">

     <user><xsl:value-of select="normalize-space(.)"/></user>

   </xsl:for-each>

 </xsl:variable>

 <xsl:variable name="sorted_users">

   <xsl:for-each select="exsl:node-set($users)/user">

     <xsl:sort/>

     <xsl:copy-of select="."/>

   </xsl:for-each>

 </xsl:variable>

 <xsl:template match="/">

   <users>

     <xsl:for-each select="exsl:node-set($sorted_users)/user">

       <xsl:if test="not(. = following-sibling::user[1])">

 	<user>

 	  <xsl:value-of select="."/>

 	  <xsl:text>@users.sourceforge.net</xsl:text>

 	</user>

       </xsl:if>

     </xsl:for-each>

   </users>

 </xsl:template>

 </xsl:stylesheet>