# HG changeset patch
# User ali@yendor.vm.bytemark.co.uk
# Date 1163665826 0
# Node ID ae7b3fa753dcf20dd8e8ab6a356b73a3a3621f66

First cut. Distintly raw around the edges:
 * Assumes it will be running in /home/ali/wk/slashem/web.scripts
 * Assumes cache directory will be in topdir
 * No build system (simple compiling and linking against libxml2)
 * No configure system (eg., tagsoup)
 * Output XML untested
 * Doesn't set bugzilla maintainer or exporter
 * Handling of artifact priorities and resolution is suspect

diff -r 000000000000 -r ae7b3fa753dc README.cache
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/README.cache	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,19 @@
+The cache directory contains the following:
+
+sf/attachments/<file_id>
+	Raw attachments as downloaded from sourceforge by sf2bz
+
+sf/artifacts/<atid>/<aid>.html
+	Tagsoup detailed artifacts as downloaded from sourceforge by sf2bz
+
+sf/users/<user_id>.html
+	Tagsoup user profiles as downloaded from sourceforge by sf2bz
+
+attachments/<file_id>.xml
+	Attachments converted to xml by sf2bz
+
+artifacts/<atid>/<aid>.xhtml
+	Conversion of detailed artifacts to xhtml by tagsoup
+
+users/<user_id>.xhtml
+	Conversion of user profiles to xhtml by tagsoup
diff -r 000000000000 -r ae7b3fa753dc attachment_descs.xsl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/attachment_descs.xsl	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,51 @@
+<?xml version="1.0"?>
+
+<!-- This style sheet takes a sourceforge artifact in html and outputs
+     the attachment descriptions that it finds. The output is as follows:
+     <attachments>
+       <attachment>
+         <attachid>###</attachid>
+	 <desc>...</desc>
+       </attachment>
+       ...
+     </attachments>
+-->
+
+<xsl:stylesheet version="1.0"
+		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+		xmlns:xhtml="http://www.w3.org/1999/xhtml"
+		exclude-result-prefixes="xhtml">
+
+<xsl:template match="xhtml:tr" mode="download">
+  <attachment>
+    <attachid>
+      <xsl:value-of select="substring-before(substring-after(xhtml:td[4]/descendant::xhtml:a/@href,'file_id='),'&amp;')"/>
+    </attachid>
+    <desc>
+      <xsl:value-of select="normalize-space(xhtml:td[3])"/>
+    </desc>
+  </attachment>
+</xsl:template>
+
+<xsl:template match="xhtml:table[preceding-sibling::xhtml:h4='Attached Files:' and xhtml:tr/xhtml:td='Download']">
+    <xsl:for-each select="xhtml:tr[descendant::xhtml:a='Download']">
+      <xsl:apply-templates select="." mode="download"/>
+    </xsl:for-each>
+</xsl:template>
+
+<xsl:template match="/">
+  <attachments>
+    <xsl:apply-templates/>
+    <!-- A null description used as a fallback for when there is no
+         description listed for an attachment. -->
+    <desc xml:id="null"/>
+  </attachments>
+</xsl:template>
+
+<xsl:template match="node()" priority="-1">
+  <xsl:apply-templates/>
+</xsl:template>
+
+<xsl:template match="text()" priority="-1"></xsl:template>
+
+</xsl:stylesheet>
diff -r 000000000000 -r ae7b3fa753dc attachment_details.xsl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/attachment_details.xsl	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,70 @@
+<?xml version="1.0"?>
+
+<!-- This stylesheet extracts some details of attachments from the artifact
+     history of a sourceforge project export. -->
+
+<xsl:stylesheet version="1.0"
+		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+		xmlns:xi="http://www.w3.org/2001/XInclude">
+
+<xsl:import href="sf2bz.xsl"/>
+
+<!-- Process a sourceforge artifact, outputting attachments as found -->
+<xsl:template name="process-artifact">
+    <xsl:apply-templates/>
+    <xsl:for-each
+      select="field[@name='artifact_history']/history[field[@name='field_name']='File Added']">
+      <xsl:variable name="file_id"
+        select="substring-before(field[@name='old_value'],':')"/>
+      <attachment>
+	<!-- isobsolete is an attribute of bugzilla:attachment, but that
+	     proves hard to deal with so we treat it as a node and fix it
+	     up in attachment_post.xsl -->
+	<isobsolete>
+	  <xsl:value-of select="number(boolean(../history[field[@name='field_name']='File Deleted' and substring-before(field[@name='old_value'],':')=$file_id]))"/>
+	</isobsolete>
+	<attachid>
+	  <xsl:value-of select="$file_id"/>
+	</attachid>
+	<date>
+	  <xsl:call-template name="bugzilla-timestamp">
+	    <xsl:with-param name="secs" select="field[@name='entrydate']"/>
+	  </xsl:call-template>
+	</date>
+	<filename>
+	  <xsl:value-of
+	    select="substring-after(field[@name='old_value'],': ')"/>
+	</filename>
+      </attachment>
+    </xsl:for-each>
+</xsl:template>
+
+<xsl:template match="project_export">
+  <attachments>
+    <xsl:apply-templates/>
+  </attachments>
+</xsl:template>
+
+<xsl:template match="artifacts">
+  <xsl:apply-templates/>
+</xsl:template>
+
+<xsl:template match="artifact">
+  <xsl:variable name="type"
+    select="normalize-space(field[@name='artifact_type'])"/>
+  <xsl:choose>
+    <xsl:when test="$type = 'Feature Requests'">
+      <xsl:call-template name="process-artifact"/>
+    </xsl:when>
+    <xsl:when test="$type = 'Patches'">
+      <xsl:call-template name="process-artifact"/>
+    </xsl:when>
+    <xsl:when test="$type = 'Bugs'">
+      <xsl:call-template name="process-artifact"/>
+    </xsl:when>
+  </xsl:choose>
+</xsl:template>
+
+<xsl:template match="node()|text()" priority="-1"></xsl:template>
+
+</xsl:stylesheet>
diff -r 000000000000 -r ae7b3fa753dc attachment_gather.xsl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/attachment_gather.xsl	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,54 @@
+<?xml version="1.0"?>
+
+<!-- This style sheet takes the output of xml_attached file (which represents
+     an attachment and it's MIME type), adds in the following extra nodes:
+       date, desc & filename.
+-->
+
+<xsl:stylesheet version="1.0"
+		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+		xmlns:xi="http://www.w3.org/2001/XInclude">
+
+<xsl:template match="attachment">
+  <xsl:copy>
+    <xsl:for-each select="@*">
+      <xsl:copy/>
+    </xsl:for-each>
+    <xsl:apply-templates/>
+    <xsl:element namespace="http://www.w3.org/2001/XInclude" name="include">
+      <xsl:attribute name="href">
+	<xsl:text>attachment-details.xml</xsl:text>
+      </xsl:attribute>
+      <xsl:attribute name="xpointer">
+	<xsl:text>xpointer(/attachments/attachment[attachid='</xsl:text>
+	<xsl:value-of select="attachid"/>
+	<xsl:text>']/*)</xsl:text>
+      </xsl:attribute>
+    </xsl:element>
+    <xsl:element namespace="http://www.w3.org/2001/XInclude" name="include">          <xsl:attribute name="href">
+	<xsl:text>attachment-descriptions.xml</xsl:text>
+      </xsl:attribute>
+      <xsl:attribute name="xpointer">
+	<xsl:text>xpointer(/attachments/attachment[attachid='</xsl:text>
+	<xsl:value-of select="attachid"/>
+	<xsl:text>']/desc)element(null)</xsl:text>
+      </xsl:attribute>
+    </xsl:element>
+  </xsl:copy>
+</xsl:template>
+
+<!-- Drop the attachment ID to avoid duplication with the node included
+     from attachment-details.xml -->
+
+<xsl:template match="attachid"/>
+
+<xsl:template match="*">
+  <xsl:copy>
+    <xsl:for-each select="@*">
+      <xsl:copy/>
+    </xsl:for-each>
+    <xsl:apply-templates/>
+  </xsl:copy>
+</xsl:template>
+
+</xsl:stylesheet>
diff -r 000000000000 -r ae7b3fa753dc attachment_post.xsl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/attachment_post.xsl	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,38 @@
+<?xml version="1.0"?>
+
+<!-- This stylesheet does some post-processing on attachments. -->
+
+<xsl:stylesheet version="1.0"
+		xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
+
+<xsl:template match="attachment">
+  <!-- Avoid xsl:copy so that any attributes (including xml:base) are lost -->
+  <attachment>
+    <xsl:attribute name="ispatch">
+      <xsl:value-of select="@ispatch"/>
+    </xsl:attribute>
+    <xsl:attribute name="isobsolete">
+      <xsl:value-of select="isobsolete"/>
+    </xsl:attribute>
+    <xsl:apply-templates/>
+  </attachment>
+</xsl:template>
+
+<xsl:template match="attachment/isobsolete"/>
+
+<xsl:template match="attachment/desc[normalize-space(.)='']">
+  <desc>
+    <xsl:value-of select="../filename"/>
+  </desc>
+</xsl:template>
+
+<xsl:template match="*">
+  <xsl:copy>
+    <xsl:for-each select="@*">
+      <xsl:copy/>
+    </xsl:for-each>
+    <xsl:apply-templates/>
+  </xsl:copy>
+</xsl:template>
+
+</xsl:stylesheet>
diff -r 000000000000 -r ae7b3fa753dc bugzilla.xsl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/bugzilla.xsl	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,236 @@
+<?xml version="1.0"?>
+<xsl:stylesheet version="1.0"
+		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+		xmlns:xi="http://www.w3.org/2001/XInclude"
+		xmlns:date="http://exslt.org/dates-and-times"
+		xmlns:sf2bz="http://project.juiblex.co.uk/sf2bz"
+		extension-element-prefixes="date">
+
+<xsl:import href="sf2bz.xsl"/>
+
+<!-- Return the last change made in an artifact's history -->
+<xsl:template name="lastchange">
+  <xsl:variable name="dates">
+    <xsl:for-each
+      select="field[@name='artifact_history']/history/field[@name='entrydate']">
+      <xsl:sort data-type='number' order='descending'/>
+      <xsl:value-of select="."/>
+      <xsl:text>:</xsl:text>
+    </xsl:for-each>
+  </xsl:variable>
+  <xsl:call-template name="bugzilla-timestamp">
+    <xsl:with-param name="secs" select="substring-before($dates,':')"/>
+  </xsl:call-template>
+</xsl:template>
+
+<!-- Process a sourceforge artifact, outputting a bugzilla bug -->
+<xsl:template name="process-artifact">
+  <bug>
+    <xsl:apply-templates/>
+    <delta_ts>
+      <xsl:choose>
+	<xsl:when test="field[@name='artifact_history']">
+	  <xsl:call-template name="lastchange"/>
+	</xsl:when>
+	<xsl:otherwise>
+	  <xsl:call-template name="bugzilla-timestamp">
+	    <xsl:with-param name="secs" select="field[@name='open_date']"/>
+	  </xsl:call-template>
+	</xsl:otherwise>
+      </xsl:choose>
+    </delta_ts>
+    <xsl:for-each
+      select="field[@name='artifact_history']/history[field[@name='field_name']='File Added']">
+      <xsl:element namespace="http://www.w3.org/2001/XInclude" name="include">
+	<xsl:attribute name="href">
+	  <xsl:text>cache/attachments/</xsl:text>
+	  <xsl:value-of
+	    select="substring-before(field[@name='old_value'],':')"/>
+	  <xsl:text>.xml</xsl:text>
+	</xsl:attribute>
+	<xsl:attribute name="xpointer">xpointer(/attachment)</xsl:attribute>
+	<xsl:element namespace="http://www.w3.org/2001/XInclude"
+	  name="fallback"/>
+      </xsl:element>
+    </xsl:for-each>
+  </bug>
+</xsl:template>
+
+<!-- Output a user node -->
+<xsl:template name="bugzilla-user">
+  <xsl:param name="element">who</xsl:param>
+  <xsl:param name="user" select="."/>
+  <sf2bz:element>
+    <xsl:attribute name="name">
+      <xsl:value-of select="$element"/>
+    </xsl:attribute>
+    <sf2bz:copy-from>
+      <xsl:element namespace="http://www.w3.org/2001/XInclude" name="include">
+	<xsl:attribute name="href">users.xml</xsl:attribute>
+	<xsl:attribute name="xpointer">
+	  <xsl:text>xpointer(/users/user[.="</xsl:text>
+	  <xsl:value-of select="$user"/>
+	  <xsl:text>@users.sourceforge.net"])</xsl:text>
+	</xsl:attribute>
+      </xsl:element>
+    </sf2bz:copy-from>
+  </sf2bz:element>
+</xsl:template>
+
+<xsl:template match="project_export">
+  <bugzilla version="2.23.3">
+    <xsl:if test="news/field[@name='group_id']/@group_id">
+      <xsl:attribute name="urlbase">
+        <xsl:text>https://sourceforge.net/tracker/?group_id=</xsl:text>
+	<xsl:value-of select="news/field[@name='group_id']/@group_id"/>
+      </xsl:attribute>
+    </xsl:if>
+    <xsl:apply-templates/>
+  </bugzilla>
+</xsl:template>
+
+<xsl:template match="artifacts">
+  <xsl:apply-templates/>
+</xsl:template>
+
+<xsl:template match="artifact">
+  <xsl:variable name="type"
+    select="normalize-space(field[@name='artifact_type'])"/>
+  <xsl:choose>
+    <xsl:when test="$type = 'Feature Requests'">
+      <xsl:call-template name="process-artifact"/>
+    </xsl:when>
+    <xsl:when test="$type = 'Patches'">
+      <xsl:call-template name="process-artifact"/>
+    </xsl:when>
+    <xsl:when test="$type = 'Bugs'">
+      <xsl:call-template name="process-artifact"/>
+    </xsl:when>
+  </xsl:choose>
+</xsl:template>
+
+<xsl:template match="field[@name='artifact_id']">
+  <bug_id><xsl:value-of select="."/></bug_id>
+</xsl:template>
+
+<xsl:template match="field[@name='submitted_by']">
+  <xsl:call-template name="bugzilla-user">
+    <xsl:with-param name="element">reporter</xsl:with-param>
+  </xsl:call-template>
+</xsl:template>
+
+<xsl:template match="field[@name='assigned_to']">
+  <xsl:if test="normalize-space(.)!='nobody'">
+    <xsl:call-template name="bugzilla-user">
+      <xsl:with-param name="element">assigned_to</xsl:with-param>
+    </xsl:call-template>
+  </xsl:if>
+</xsl:template>
+
+<xsl:template match="field[@name='priority']">
+  <priority>
+    <xsl:choose>
+      <xsl:when test="number(.)>8">P5</xsl:when>
+      <xsl:when test="number(.)>5">P4</xsl:when>
+      <xsl:when test="number(.)=5">P3</xsl:when>
+      <xsl:when test="number(.)>1">P2</xsl:when>
+      <xsl:otherwise>P1</xsl:otherwise>
+    </xsl:choose>
+  </priority>
+</xsl:template>
+
+<xsl:template match="field[@name='status']">
+  <bug_status>
+    <xsl:choose>
+      <xsl:when test="normalize-space(.)='Open'">
+	<xsl:choose>
+	  <xsl:when
+	    test="normalize-space(../field[@name='assigned_to'])='nobody'">
+	    <xsl:text>UNCONFIRMED</xsl:text>
+	  </xsl:when>
+	  <xsl:otherwise>ASSIGNED</xsl:otherwise>
+	</xsl:choose>
+      </xsl:when>
+      <xsl:when test="normalize-space(.)='Pending'">NEW</xsl:when>
+      <xsl:otherwise>RESOLVED</xsl:otherwise>
+    </xsl:choose>
+  </bug_status>
+</xsl:template>
+
+<xsl:template match="field[@name='summary']">
+  <short_desc><xsl:value-of select="."/></short_desc>
+</xsl:template>
+
+<xsl:template match="field[@name='open_date']">
+  <creation_ts>
+    <xsl:call-template name="bugzilla-timestamp"/>
+  </creation_ts>
+</xsl:template>
+
+<xsl:template match="field[@name='artifact_type']">
+  <xsl:variable name="pri"
+    select="normalize-space(../field[@name='priority'])"/>
+  <bug_severity>
+    <xsl:choose>
+      <xsl:when test="normalize-space(.)='Bugs'">
+	<xsl:choose>
+	  <xsl:when test="$pri&gt;=9">blocker</xsl:when>
+	  <xsl:when test="$pri=8">critical</xsl:when>
+	  <xsl:when test="$pri&lt;8 and $pri&gt;5">major</xsl:when>
+	  <xsl:when test="$pri&lt;5 and $pri&gt;2">minor</xsl:when>
+	  <xsl:when test="$pri&lt;=2">trivial</xsl:when>
+	  <xsl:otherwise>normal</xsl:otherwise>
+	</xsl:choose>
+      </xsl:when>
+      <xsl:otherwise>enhancement</xsl:otherwise>
+    </xsl:choose>
+  </bug_severity>
+</xsl:template>
+
+<xsl:template match="field[@name='category']">
+  <component><xsl:value-of select="."/></component>
+</xsl:template>
+
+<xsl:template match="field[@name='artifact_group_id']">
+  <version><xsl:value-of select="."/></version>
+</xsl:template>
+
+<xsl:template match="field[@name='details']">
+  <long-desc>
+    <xsl:call-template name="bugzilla-user">
+      <xsl:with-param name="user" select="../field[@name='submitted_by']"/>
+    </xsl:call-template>
+    <bug_when>
+      <xsl:call-template name="bugzilla-timestamp">
+	<xsl:with-param name="secs" select="../field[@name='open_date']"/>
+      </xsl:call-template>
+    </bug_when>
+    <thetext><xsl:value-of select="."/></thetext>
+  </long-desc>
+</xsl:template>
+
+<xsl:template match="field[@name='artifact_messages']">
+  <xsl:apply-templates/>
+</xsl:template>
+
+<xsl:template match="message">
+  <long-desc>
+    <xsl:call-template name="bugzilla-user">
+      <xsl:with-param name="user" select="field[@name='user_name']"/>
+    </xsl:call-template>
+    <bug_when>
+      <xsl:call-template name="bugzilla-timestamp">
+	<xsl:with-param name="secs" select="field[@name='adddate']"/>
+      </xsl:call-template>
+    </bug_when>
+    <thetext>
+      <!-- Sourceforge puts either "Logged In: YES \n;user_id=%user\n\n" or
+           "Logged In: NO\n\n" at the start of each message body. -->
+      <xsl:value-of select="substring-after(field[@name='body'],'&#10;&#10;')"/>
+    </thetext>
+  </long-desc>
+</xsl:template>
+
+<xsl:template match="node()|text()" priority="-1"></xsl:template>
+
+</xsl:stylesheet>
diff -r 000000000000 -r ae7b3fa753dc bugzilla_post.xsl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/bugzilla_post.xsl	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,31 @@
+<?xml version="1.0"?>
+
+<!-- This stylesheet does some post-processing on the bugzilla output. -->
+
+<xsl:stylesheet version="1.0"
+		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+		xmlns:sf2bz="http://project.juiblex.co.uk/sf2bz"
+		exclude-result-prefixes="sf2bz">
+
+<xsl:template match="//sf2bz:element">
+  <xsl:element name="{@name}">
+    <xsl:for-each select="sf2bz:copy-from/*/*|sf2bz:copy-from/*/@*|sf2bz:copy-from/*/text()">
+      <xsl:copy/>
+    </xsl:for-each>
+  </xsl:element>
+</xsl:template>
+
+<!-- Kill all the xmlns:* and xml:base attributes
+     (none of which are relevant any more) -->
+<xsl:template match="*">
+  <xsl:element name="{name()}">
+    <xsl:for-each select="@*">
+      <xsl:if test="name(.) != 'xml:base'">
+	<xsl:copy/>
+      </xsl:if>
+    </xsl:for-each>
+    <xsl:apply-templates/>
+  </xsl:element>
+</xsl:template>
+
+</xsl:stylesheet>
diff -r 000000000000 -r ae7b3fa753dc get_attached_files.c
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/get_attached_files.c	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,148 @@
+/*
+ * This program parses the XML data provided by sourceforge to extract the
+ * list of "attached files" (which are not themselves included in the XML
+ * stream and therefore need to be seperately downloaded for archiving).
+ */
+
+#include <stdlib.h>
+#include <stdio.h>
+#include <string.h>
+#include <libxml/xmlmemory.h>
+#include <libxml/parser.h>
+
+struct artifact_type {
+    char *name;
+    int id;
+} artifact_types[] = {
+    "Bugs",		109746,
+    "Support Requests",	209746,
+    "Patches",		309746,
+    "Feature Requests",	359746,
+};
+
+#ifndef NO_ELEMS
+#define NO_ELEMS(array)	(sizeof(array)/sizeof(*(array)))
+#endif
+
+void parse_history(xmlDocPtr doc,const xmlChar *artifact_id,
+  const xmlChar *artifact_type,xmlNodePtr node)
+{
+    xmlNodePtr field,cur;
+    xmlAttrPtr attr;
+    xmlChar *name=NULL;
+    xmlChar *field_name=NULL;
+    xmlChar *text;
+    int file_id,i;
+    for(field=node->xmlChildrenNode;field;field=field->next)
+	if (!xmlStrcmp(field->name,(const xmlChar *)"field"))
+	{
+	    for(attr=field->properties;attr;attr=attr->next)
+		if (!xmlStrcmp(attr->name,(const xmlChar *)"name"))
+		{
+		    name=xmlNodeListGetString(doc,attr->children,1);
+		    if (!xmlStrcmp(name,(const xmlChar *)"field_name"))
+			field_name=xmlNodeListGetString(doc,field->children,1);
+		    if (!xmlStrcmp(field_name,(const xmlChar *)"File Added") &&
+		      !xmlStrcmp(name,(const xmlChar *)"old_value"))
+		    {
+			text=xmlNodeListGetString(doc,field->children,1);
+			if (sscanf(text,"%d",&file_id)==1)
+			{
+			    for(i=NO_ELEMS(artifact_types)-1;i>=0;i--)
+				if (!strcmp(artifact_types[i].name,
+				  (const char *)artifact_type))
+				    break;
+			    if (i>=0)
+				printf("%d %s %d\n",
+				  artifact_types[i].id,artifact_id,file_id);
+			    else
+				fprintf(stderr,
+				  "Warning: Unknown artifact type \"%s\" - "
+				  "attached file %s ignored\n",
+				  artifact_type,text);
+			}
+			xmlFree(text);
+		    }
+		    xmlFree(name);
+		}
+	}
+    if (field_name)
+	xmlFree(field_name);
+}
+
+void parse_artifact(xmlDocPtr doc,xmlNodePtr node)
+{
+    xmlNodePtr field,cur;
+    xmlAttrPtr attr;
+    xmlChar *name=NULL;
+    xmlChar *id=NULL;
+    xmlChar *type=NULL;
+    xmlChar *text;
+    for(field=node->xmlChildrenNode;field;field=field->next)
+	if (!xmlStrcmp(field->name,(const xmlChar *)"field"))
+	{
+	    for(attr=field->properties;attr;attr=attr->next)
+		if (!xmlStrcmp(attr->name,(const xmlChar *)"name"))
+		{
+		    name=xmlNodeListGetString(doc,attr->children,1);
+		    if (!xmlStrcmp(name,(const xmlChar *)"artifact_id"))
+			id=xmlNodeListGetString(doc,field->children,1);
+		    if (!xmlStrcmp(name,(const xmlChar *)"artifact_type"))
+			type=xmlNodeListGetString(doc,field->children,1);
+		}
+	    if (!xmlStrcmp(name,(const xmlChar *)"artifact_history"))
+		for(cur=field->xmlChildrenNode;cur;cur=cur->next)
+		    if (!xmlStrcmp(cur->name,"history"))
+			parse_history(doc,id,type,cur);
+	    if (name)
+	    {
+		xmlFree(name);
+		name=NULL;
+	    }
+	}
+    if (id)
+	xmlFree(id);
+    if (type)
+	xmlFree(type);
+}
+
+int main(int argc,char **argv)
+{
+    xmlDocPtr doc;
+    xmlNodePtr cur;
+    doc=xmlParseFile(argv[1]);
+    if (!doc)
+    {
+	fprintf(stderr,"Document not parsed successfully.\n");
+	exit(1);
+    }
+    cur=xmlDocGetRootElement(doc);
+    if (!cur)
+    {
+	fprintf(stderr,"Empty document.\n");
+	xmlFreeDoc(doc);
+	exit(1);
+    }
+    if (xmlStrcmp(cur->name,(const xmlChar *)"project_export"))
+    {
+	fprintf(stderr,"%s does not appear to be a project export document.\n",
+	  argv[1]);
+	xmlFreeDoc(doc);
+	exit(1);
+    }
+    for(cur=cur->xmlChildrenNode;cur;cur=cur->next)
+	if (!xmlStrcmp(cur->name,(const xmlChar *)"artifacts"))
+	    break;
+    if (!cur)
+    {
+	fprintf(stderr,"%s does not appear to contain an artifacts node.\n",
+	  argv[1]);
+	xmlFreeDoc(doc);
+	exit(1);
+    }
+    for(cur=cur->xmlChildrenNode;cur;cur=cur->next)
+	if (!xmlStrcmp(cur->name,(const xmlChar *)"artifact"))
+	    parse_artifact(doc,cur);
+    xmlFreeDoc(doc);
+    exit(0);
+}
diff -r 000000000000 -r ae7b3fa753dc get_users.xsl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/get_users.xsl	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,39 @@
+<?xml version="1.0"?>
+<xsl:stylesheet version="1.0"
+		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+		xmlns:exsl="http://exslt.org/common"
+		extension-element-prefixes="exsl">
+
+<xsl:variable name="users">
+  <xsl:for-each select="//artifact/field[@name='submitted_by' or @name='assigned_to']">
+    <user><xsl:value-of select="normalize-space(.)"/></user>
+  </xsl:for-each>
+  <xsl:for-each select="//artifact/field[@name='artifact_history']/history/field[@name='mod_by']">
+    <user><xsl:value-of select="normalize-space(.)"/></user>
+  </xsl:for-each>
+  <xsl:for-each select="//artifact/field[@name='artifact_messages']/message/field[@name='user_name']">
+    <user><xsl:value-of select="normalize-space(.)"/></user>
+  </xsl:for-each>
+</xsl:variable>
+
+<xsl:variable name="sorted_users">
+  <xsl:for-each select="exsl:node-set($users)/user">
+    <xsl:sort/>
+    <xsl:copy-of select="."/>
+  </xsl:for-each>
+</xsl:variable>
+
+<xsl:template match="/">
+  <users>
+    <xsl:for-each select="exsl:node-set($sorted_users)/user">
+      <xsl:if test="not(. = following-sibling::user[1])">
+	<user>
+	  <xsl:value-of select="."/>
+	  <xsl:text>@users.sourceforge.net</xsl:text>
+	</user>
+      </xsl:if>
+    </xsl:for-each>
+  </users>
+</xsl:template>
+
+</xsl:stylesheet>
diff -r 000000000000 -r ae7b3fa753dc sf2bz.sh
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/sf2bz.sh	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,109 @@
+#!/bin/sh
+if [ $# -ne 2 ]; then
+    echo "Usage: sf2bz <sf-project-export>.xml <bz-import>.xml" >&2
+    exit 1
+fi
+input=$1
+output=$2
+topdir=/home/ali/wk/slashem/web.scripts
+cd $topdir
+cache_dir=$topdir/cache
+tagsoup=tagsoup/tagsoup-1.0.1.jar
+#tmpdir=`mktemp -d /tmp/XXXXXXXX` || exit 1
+tmpdir=/tmp/sf2bz; rm -rf $tmpdir; mkdir $tmpdir
+mkdir -p $cache_dir/sf/artifacts
+# Sourceforge's export is pretty good, but misses a few things.
+# Deal with one of these (descriptions for attached files) here.
+echo '<?xml version="1.0"?>' > $tmpdir/descriptions.xml
+echo '<artifacts xmlns:xi="http://www.w3.org/2001/XInclude">' \
+  >> $tmpdir/descriptions.xml
+./get_attached_files $input | cut -s "-d " -f 1,2 | sort -n | uniq | \
+  while read atid aid; do
+    mkdir -p $cache_dir/sf/artifacts/$atid
+    if [ ! -r $cache_dir/sf/artifacts/$atid/$aid.html ]; then
+	wget -q -O $cache_dir/sf/artifacts/$atid/$aid.html \
+	  "http://sourceforge.net/tracker/index.php?func=detail&aid=$aid&group_id=9746&atid=$atid"
+    fi
+    mkdir -p $cache_dir/artifacts/$atid
+    if [ ! -r $cache_dir/artifacts/$atid/$aid.xhtml ]; then
+	java -jar $tagsoup $cache_dir/sf/artifacts/$atid/$aid.html \
+	  > $cache_dir/artifacts/$atid/$aid.xhtml
+    fi
+    echo "<xi:include href=\"$cache_dir/artifacts/$atid/$aid.xhtml\"/>" >> $tmpdir/descriptions.xml
+done
+echo '</artifacts>' >> $tmpdir/descriptions.xml
+xsltproc --xinclude attachment_descs.xsl $tmpdir/descriptions.xml \
+  > $tmpdir/attachment-descriptions.xml
+# Some details of attachments are included in the project export.
+xsltproc attachment_details.xsl $input > $tmpdir/attachment-details.xml
+# Then convert the attachments to XML (as required by bugzilla)
+# pulling in the various bits of information we have gathered.
+mkdir -p $cache_dir/sf/attachments $cache_dir/attachments
+mkdir -p $tmpdir/jail
+./get_attached_files artifacts.xml | while read atid aid file_id; do
+    if [ ! -r $cache_dir/sf/attachments/$file_id ]; then
+	wget -N -O $cache_dir/sf/attachments/$file_id "http://sourceforge.net/tracker/download.php?group_id=9746&atid=$atid&file_id=$file_id&aid=$aid"
+    fi
+    if [ ! -r $cache_dir/attachments/$file_id.xml ]; then
+	type=`file -bi $cache_dir/sf/attachments/$file_id | sed 's/;.*//'`
+	case "$type" in
+	    text/*)
+		(cd $tmpdir/jail; patch --dry-run -s -f \
+		  < $cache_dir/sf/attachments/$file_id > /dev/null 2>&1)
+		if [ $? -lt 2 ]; then
+		    pflag="-p"
+		else
+		    pflag=""
+		fi
+		;;
+	    *)
+	        pflag=""
+		;;
+	esac
+	./xml_attached_file $pflag -i $file_id -t $type \
+	  $cache_dir/sf/attachments/$file_id > $tmpdir/$file_id.1.xml
+	xsltproc attachment_gather.xsl $tmpdir/$file_id.1.xml \
+	  > $tmpdir/$file_id.2.xml
+	xsltproc --xinclude attachment_post.xsl $tmpdir/$file_id.2.xml \
+	  > $cache_dir/attachments/$file_id.xml
+    fi
+done
+# We can't get hold of descriptions of deleted attachments, so we
+# keep a copy of the file in case we need it. Ideally, we'd make sure
+# that we only add descriptions, but that's for another day.
+cp $tmpdir/attachment-descriptions.xml $topdir
+xsltproc get_users.xsl $input > $tmpdir/raw_users.xml
+echo '<artifacts xmlns:xi="http://www.w3.org/2001/XInclude">' \
+  >> $tmpdir/users.1.xml
+for file in $cache_dir/artifacts/*/*.xhtml; do
+    echo "<xi:include href=\"$file\"/>" >> $tmpdir/users.1.xml
+done
+echo "<xi:include href=\"raw_users.xml\"/>" >> $tmpdir/users.1.xml
+echo '</artifacts>' >> $tmpdir/users.1.xml
+xsltproc --xinclude user_names.xsl $tmpdir/users.1.xml > $tmpdir/users.2.xml
+mkdir -p $cache_dir/sf/users $cache_dir/users
+echo '<sf_users xmlns:xi="http://www.w3.org/2001/XInclude">' \
+  >> $tmpdir/users.3.xml
+xsltproc unknown_users.xsl $tmpdir/users.2.xml | while read user; do
+    case $user in
+	*@users.sourceforge.net)
+	    user_id=`echo $user | sed 's/@users.sourceforge.net$//'`
+	    if [ ! -r $cache_dir/sf/users/$user_id.html ]; then
+		wget -N -O $cache_dir/sf/users/$user_id.html \
+		  "http://sourceforge.net/users/$user_id/"
+	    fi
+	    if [ ! -r $cache_dir/users/$user_id.xhtml ]; then
+		java -jar $tagsoup $cache_dir/sf/users/$user_id.html \
+		  > $cache_dir/users/$user_id.xhtml
+	    fi
+	    echo "<xi:include href=\"$cache_dir/users/$user_id.xhtml\"/>" \
+	      >> $tmpdir/users.3.xml
+    esac
+done
+echo "<xi:include href=\"users.2.xml\"/>" >> $tmpdir/users.3.xml
+echo '</sf_users>' >> $tmpdir/users.3.xml
+xsltproc --xinclude user_names.xsl $tmpdir/users.3.xml > users.xml
+ln -s $cache_dir/attachments $tmpdir
+xsltproc bugzilla.xsl $input > artifacts.tmp.xml
+xsltproc --xinclude bugzilla_post.xsl artifacts.tmp.xml > $output
+#rm -rf $tmpdir artifacts.tmp.xml
diff -r 000000000000 -r ae7b3fa753dc sf2bz.xsl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/sf2bz.xsl	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,29 @@
+<?xml version="1.0"?>
+
+<!-- A set of templates used in multiple stylesheets -->
+
+<xsl:stylesheet version="1.0"
+		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+		xmlns:date="http://exslt.org/dates-and-times"
+		extension-element-prefixes="date">
+
+<!-- Convert a UNIX-style date (seconds since 1 Jan 1970) to
+     the timestamp format used by bugzilla: %Y-%m-%d %X -->
+<xsl:template name="bugzilla-timestamp">
+  <xsl:param name="secs" select="."/>
+  <xsl:variable name="dt" select="date:add('1970',concat('PT',$secs,'S'))"/>
+  <xsl:value-of select="date:year($dt)"/>
+  <xsl:text>-</xsl:text>
+  <xsl:value-of select="format-number(date:month-in-year($dt),'00')"/>
+  <xsl:text>-</xsl:text>
+  <xsl:value-of select="format-number(date:day-in-month($dt),'00')"/>
+  <xsl:text> </xsl:text>
+  <xsl:value-of select="format-number(date:hour-in-day($dt),'00')"/>
+  <xsl:text>:</xsl:text>
+  <xsl:value-of select="format-number(date:minute-in-hour($dt),'00')"/>
+  <xsl:text>:</xsl:text>
+  <xsl:value-of select="format-number(date:second-in-minute($dt),'00')"/>
+  <xsl:text> UTC</xsl:text>
+</xsl:template>
+
+</xsl:stylesheet>
diff -r 000000000000 -r ae7b3fa753dc tagsoup/SRC
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/tagsoup/SRC	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,2 @@
+http://mercury.ccil.org/~cowan/XML/tagsoup/
+http://mercury.ccil.org/~cowan/XML/tagsoup/tagsoup-1.0.1.jar
diff -r 000000000000 -r ae7b3fa753dc unknown_users.xsl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/unknown_users.xsl	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,15 @@
+<?xml version="1.0"?>
+
+<xsl:stylesheet version="1.0"
+		xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
+
+<xsl:output method="text" encoding="utf-8"/>
+
+<xsl:template match="//users/user[not(@name)]">
+  <xsl:value-of select="."/>
+  <xsl:text>&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="text()"/>
+
+</xsl:stylesheet>
diff -r 000000000000 -r ae7b3fa753dc user_names.xsl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/user_names.xsl	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,61 @@
+<?xml version="1.0"?>
+
+<xsl:stylesheet version="1.0"
+		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+		xmlns:xhtml="http://www.w3.org/1999/xhtml"
+		xmlns:exsl="http://exslt.org/common"
+		extension-element-prefixes="exsl"
+		exclude-result-prefixes="xhtml">
+
+<xsl:variable name="users">
+  <xsl:for-each select="//users/user">
+    <user>
+      <xsl:copy-of select="@name"/>
+      <xsl:value-of select="."/>
+    </user>
+  </xsl:for-each>
+  <xsl:for-each select="//xhtml:td[xhtml:b='Submitted By:' and xhtml:a]">
+    <xsl:element name="user">
+      <xsl:attribute name="name">
+	<xsl:for-each select="text()">
+	  <xsl:if test="contains(., '-')">
+	    <xsl:value-of select="normalize-space(substring-before(., '-'))"/>
+	  </xsl:if>
+	</xsl:for-each>
+      </xsl:attribute>
+      <xsl:value-of select="xhtml:a"/>
+      <xsl:text>@users.sourceforge.net</xsl:text>
+    </xsl:element>
+  </xsl:for-each>
+  <xsl:for-each select="//xhtml:table[xhtml:tr/xhtml:td[normalize-space(.)='Login Name:'] and xhtml:tr/xhtml:td[normalize-space(.)='Publicly Displayed Name:']]">
+    <xsl:element name="user">
+      <xsl:attribute name="name">
+	<xsl:value-of select="normalize-space(xhtml:tr/xhtml:td[normalize-space(.)='Publicly Displayed Name:']/following-sibling::xhtml:td)"/>
+      </xsl:attribute>
+	<xsl:value-of select="normalize-space(xhtml:tr/xhtml:td[normalize-space(.)='Login Name:']/following-sibling::xhtml:td)"/>
+      <xsl:text>@users.sourceforge.net</xsl:text>
+    </xsl:element>
+  </xsl:for-each>
+</xsl:variable>
+
+<xsl:variable name="sorted_users">
+  <xsl:for-each select="exsl:node-set($users)/user">
+    <xsl:sort/>
+    <xsl:copy-of select="."/>
+  </xsl:for-each>
+</xsl:variable>
+
+<xsl:template match="/">
+  <users>
+    <xsl:for-each select="exsl:node-set($sorted_users)/user">
+      <xsl:if test="not(. = following-sibling::user[1])">
+	<xsl:copy>
+	  <xsl:copy-of select="@name"/>
+	  <xsl:value-of select="."/>
+	</xsl:copy>
+      </xsl:if>
+    </xsl:for-each>
+  </users>
+</xsl:template>
+
+</xsl:stylesheet>
diff -r 000000000000 -r ae7b3fa753dc xml_attached_file.c
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/xml_attached_file.c	Thu Nov 16 08:30:26 2006 +0000
@@ -0,0 +1,144 @@
+/*
+ * This program converts an attached file (which has previously been
+ * downloaded from sourceforge) into bugzilla-style XML.
+ */
+
+#include <stdlib.h>
+#include <stdio.h>
+#include <string.h>
+#ifdef __linux__
+#include <getopt.h>
+#endif
+
+#ifdef __linux__
+static struct option long_options[] = {
+    {"type", 1, 0, 't'},
+    {"id", 1, 0, 'i'},
+    {"patch", 0, 0, 'p'},
+    {0, 0, 0, 0}
+};
+
+static char *long_option_str(char opt)
+{
+    int i;
+    static char buf[100];
+    for(i=0;long_options[i].name;i++)
+	if (long_options[i].val==opt)
+	{
+	    sprintf(buf,", --%s",long_options[i].name);
+	    return buf;
+	}
+    return "";
+}
+#else
+#define long_option_str(opt)    ""
+#endif
+
+usage()
+{
+    fprintf(stderr,"Usage: xml_attached_file [OPTION] file\n");
+    fprintf(stderr,"\n");
+    fprintf(stderr,"  -t%s=MIME-type	    MIME type to use\n",
+      long_option_str('t'));
+    fprintf(stderr,"  -i%s=ID	            Attachment ID to use\n",
+      long_option_str('i'));
+    fprintf(stderr,"  -p%s	            Mark attachment as a patch\n",
+      long_option_str('p'));
+    exit(1);
+}
+
+/* Note that we limit line lengths to 76 characters following RFC 2045
+ * (bugzilla uses MIME::Base64). This isn't strictly compliant with RFC 4648.
+ */
+static void base64_encode(FILE *in,FILE *out)
+{
+    int ng=0;		/* 76 characters == 19 groups */
+    size_t nb;
+    unsigned char bytes[3];
+    const char alphabet[64]=
+      "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/";
+    while ((nb=fread(bytes,1,3,in))==3)
+    {
+	if (ng++>=19)
+	{
+	    putc('\n',out);
+	    ng=1;
+	}
+	putc(alphabet[bytes[0]>>2],out);
+	putc(alphabet[(bytes[0]<<4|bytes[1]>>4)&0x3F],out);
+	putc(alphabet[(bytes[1]<<2|bytes[2]>>6)&0x3F],out);
+	putc(alphabet[bytes[2]&0x3F],out);
+    }
+    if (nb)
+    {
+	if (ng>=19)
+	    putc('\n',out);
+	putc(alphabet[bytes[0]>>2],out);
+	if (nb==2)
+	{
+	    putc(alphabet[(bytes[0]<<4|bytes[1]>>4)&0x3F],out);
+	    putc(alphabet[bytes[1]<<2&0x3F],out);
+	}
+	else
+	{
+	    putc(alphabet[bytes[0]<<4&0x3F],out);
+	    putc('=',out);
+	}
+	putc('=',out);
+    }
+}
+
+int main(int argc,char **argv)
+{
+    int c;
+    FILE *fp;
+    unsigned long id=0;
+    int ispatch=0;
+    char *type=NULL;
+    for(;;)
+    {
+#ifdef __linux__
+	int option_index=0;
+	c=getopt_long(argc,argv,"t:i:p",long_options,&option_index);
+#else
+	c=getopt(argc,argv,"t:i:p");
+#endif
+	if (c<0)
+	    break;
+	switch(c)
+	{
+	    case 't':
+		type=optarg;
+		break;
+	    case 'i':
+		id=strtoul(optarg,NULL,10);
+		break;
+	    case 'p':
+		ispatch=1;
+		break;
+	    default:
+		usage();
+	}
+    }
+    if (optind<argc)
+    {
+	fp=fopen(argv[optind],"rb");
+	if (!fp)
+	{
+	    perror(argv[optind]);
+	    exit(1);
+	}
+    }
+    else
+	fp=stdin;
+    printf("<attachment ispatch=\"%d\">\n",ispatch);
+    if (id)
+	printf("  <attachid>%lu</attachid>\n",id);
+    if (type)
+	printf("  <type>%s</type>\n",type);
+    printf("  <data encoding=\"base64\">\n");
+    base64_encode(fp,stdout);
+    printf("\n  </data>\n");
+    printf("</attachment>\n");
+    exit(0);
+}