<?xml version="1.0"?>

<xsl:stylesheet version="1.0"

		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"

		xmlns:xi="http://www.w3.org/2001/XInclude"

		xmlns:date="http://exslt.org/dates-and-times"

		xmlns:sf2bz="http://project.juiblex.co.uk/sf2bz"

		extension-element-prefixes="date">

<xsl:import href="sf2bz.xsl"/>

<!-- Return the last change made in an artifact's history -->

<xsl:template name="lastchange">

  <xsl:variable name="dates">

    <xsl:for-each

      select="field[@name='artifact_history']/history/field[@name='entrydate']">

      <xsl:sort data-type='number' order='descending'/>

      <xsl:value-of select="."/>

      <xsl:text>:</xsl:text>

    </xsl:for-each>

  </xsl:variable>

  <xsl:call-template name="bugzilla-timestamp">

    <xsl:with-param name="secs" select="substring-before($dates,':')"/>

  </xsl:call-template>

</xsl:template>

<!-- Process a sourceforge artifact, outputting a bugzilla bug -->

<xsl:template name="process-artifact">

  <bug>

    <xsl:apply-templates/>

    <delta_ts>

      <xsl:choose>

	<xsl:when test="field[@name='artifact_history']">

	  <xsl:call-template name="lastchange"/>

	</xsl:when>

	<xsl:otherwise>

	  <xsl:call-template name="bugzilla-timestamp">

	    <xsl:with-param name="secs" select="field[@name='open_date']"/>

	  </xsl:call-template>

	</xsl:otherwise>

      </xsl:choose>

    </delta_ts>

    <xsl:for-each

      select="field[@name='artifact_history']/history[field[@name='field_name']='File Added']">

      <xsl:element namespace="http://www.w3.org/2001/XInclude" name="include">

	<xsl:attribute name="href">

	  <xsl:text>cache/attachments/</xsl:text>

	  <xsl:value-of

	    select="substring-before(field[@name='old_value'],':')"/>

	  <xsl:text>.xml</xsl:text>

	</xsl:attribute>

	<xsl:attribute name="xpointer">xpointer(/attachment)</xsl:attribute>

	<xsl:element namespace="http://www.w3.org/2001/XInclude"

	  name="fallback"/>

      </xsl:element>

    </xsl:for-each>

  </bug>

</xsl:template>

<!-- Output a user node -->

<xsl:template name="bugzilla-user">

  <xsl:param name="element">who</xsl:param>

  <xsl:param name="user" select="."/>

  <sf2bz:element>

    <xsl:attribute name="name">

      <xsl:value-of select="$element"/>

    </xsl:attribute>

    <sf2bz:copy-from>

      <xsl:element namespace="http://www.w3.org/2001/XInclude" name="include">

	<xsl:attribute name="href">users.xml</xsl:attribute>

	<xsl:attribute name="xpointer">

	  <xsl:text>xpointer(/users/user[.="</xsl:text>

	  <xsl:value-of select="$user"/>

	  <xsl:text>@users.sourceforge.net"])</xsl:text>

	</xsl:attribute>

      </xsl:element>

    </sf2bz:copy-from>

  </sf2bz:element>

</xsl:template>

<xsl:template match="project_export">

  <bugzilla version="2.23.3">

    <xsl:if test="news/field[@name='group_id']/@group_id">

      <xsl:attribute name="urlbase">

        <xsl:text>https://sourceforge.net/tracker/?group_id=</xsl:text>

	<xsl:value-of select="news/field[@name='group_id']/@group_id"/>

      </xsl:attribute>

    </xsl:if>

    <xsl:apply-templates/>

  </bugzilla>

</xsl:template>

<xsl:template match="artifacts">

  <xsl:apply-templates/>

</xsl:template>

<xsl:template match="artifact">

  <xsl:variable name="type"

    select="normalize-space(field[@name='artifact_type'])"/>

  <xsl:choose>

    <xsl:when test="$type = 'Feature Requests'">

      <xsl:call-template name="process-artifact"/>

    </xsl:when>

    <xsl:when test="$type = 'Patches'">

      <xsl:call-template name="process-artifact"/>

    </xsl:when>

    <xsl:when test="$type = 'Bugs'">

      <xsl:call-template name="process-artifact"/>

    </xsl:when>

  </xsl:choose>

</xsl:template>

<xsl:template match="field[@name='artifact_id']">

  <bug_id><xsl:value-of select="."/></bug_id>

</xsl:template>

<xsl:template match="field[@name='submitted_by']">

  <xsl:call-template name="bugzilla-user">

    <xsl:with-param name="element">reporter</xsl:with-param>

  </xsl:call-template>

</xsl:template>

<xsl:template match="field[@name='assigned_to']">

  <xsl:if test="normalize-space(.)!='nobody'">

    <xsl:call-template name="bugzilla-user">

      <xsl:with-param name="element">assigned_to</xsl:with-param>

    </xsl:call-template>

  </xsl:if>

</xsl:template>

<xsl:template match="field[@name='priority']">

  <priority>

    <xsl:choose>

      <xsl:when test="number(.)>8">P5</xsl:when>

      <xsl:when test="number(.)>5">P4</xsl:when>

      <xsl:when test="number(.)=5">P3</xsl:when>

      <xsl:when test="number(.)>1">P2</xsl:when>

      <xsl:otherwise>P1</xsl:otherwise>

    </xsl:choose>

  </priority>

</xsl:template>

<xsl:template match="field[@name='status']">

  <bug_status>

    <xsl:choose>

      <xsl:when test="normalize-space(.)='Open'">

	<xsl:choose>

	  <xsl:when

	    test="normalize-space(../field[@name='assigned_to'])='nobody'">

	    <xsl:text>UNCONFIRMED</xsl:text>

	  </xsl:when>

	  <xsl:otherwise>ASSIGNED</xsl:otherwise>

	</xsl:choose>

      </xsl:when>

      <xsl:when test="normalize-space(.)='Pending'">NEW</xsl:when>

      <xsl:otherwise>RESOLVED</xsl:otherwise>

    </xsl:choose>

  </bug_status>

</xsl:template>

<xsl:template match="field[@name='summary']">

  <short_desc><xsl:value-of select="."/></short_desc>

</xsl:template>

<xsl:template match="field[@name='open_date']">

  <creation_ts>

    <xsl:call-template name="bugzilla-timestamp"/>

  </creation_ts>

</xsl:template>

<xsl:template match="field[@name='artifact_type']">

  <xsl:variable name="pri"

    select="normalize-space(../field[@name='priority'])"/>

  <bug_severity>

    <xsl:choose>

      <xsl:when test="normalize-space(.)='Bugs'">

	<xsl:choose>

	  <xsl:when test="$pri&gt;=9">blocker</xsl:when>

	  <xsl:when test="$pri=8">critical</xsl:when>

	  <xsl:when test="$pri&lt;8 and $pri&gt;5">major</xsl:when>

	  <xsl:when test="$pri&lt;5 and $pri&gt;2">minor</xsl:when>

	  <xsl:when test="$pri&lt;=2">trivial</xsl:when>

	  <xsl:otherwise>normal</xsl:otherwise>

	</xsl:choose>

      </xsl:when>

      <xsl:otherwise>enhancement</xsl:otherwise>

    </xsl:choose>

  </bug_severity>

</xsl:template>

<xsl:template match="field[@name='category']">

  <component><xsl:value-of select="."/></component>

</xsl:template>

<xsl:template match="field[@name='artifact_group_id']">

  <version><xsl:value-of select="."/></version>

</xsl:template>

<xsl:template match="field[@name='details']">

  <long-desc>

    <xsl:call-template name="bugzilla-user">

      <xsl:with-param name="user" select="../field[@name='submitted_by']"/>

    </xsl:call-template>

    <bug_when>

      <xsl:call-template name="bugzilla-timestamp">

	<xsl:with-param name="secs" select="../field[@name='open_date']"/>

      </xsl:call-template>

    </bug_when>

    <thetext><xsl:value-of select="."/></thetext>

  </long-desc>

</xsl:template>

<xsl:template match="field[@name='artifact_messages']">

  <xsl:apply-templates/>

</xsl:template>

<xsl:template match="message">

  <long-desc>

    <xsl:call-template name="bugzilla-user">

      <xsl:with-param name="user" select="field[@name='user_name']"/>

    </xsl:call-template>

    <bug_when>

      <xsl:call-template name="bugzilla-timestamp">

	<xsl:with-param name="secs" select="field[@name='adddate']"/>

      </xsl:call-template>

    </bug_when>

    <thetext>

      <!-- Sourceforge puts either "Logged In: YES \n;user_id=%user\n\n" or

           "Logged In: NO\n\n" at the start of each message body. -->

      <xsl:value-of select="substring-after(field[@name='body'],'&#10;&#10;')"/>

    </thetext>

  </long-desc>

</xsl:template>

<xsl:template match="node()|text()" priority="-1"></xsl:template>

</xsl:stylesheet>